myDearFriend! a écrit : Re Titom1978,

Tout d'abord, si tu veux augmenter tes chances d'obtenir réponse à tes questions, je te conseille vivement d'enregistrer tes fichiers Excel dans un format compatible avec les versions Excel autres que 2007 (extension .xls). Ton sujet peut intéresser d'autres visiteurs ou intervenants qui ne possèdent malheureusement pas tous XL2007...

Cela dit, tu trouveras en pièce jointe une façon de faire.

Bien sûr, pour ma part, ce sera l'usage d'une Function personnalisée comme critère du format conditionnel :

Function HorsDelai(T1 As Date, T2 As Date, Optional DureeHMax As Date = "06:00:00", Optional HorTMin As Date = "08:00:00", Optional HorTMax As Date = "20:00:00") As Boolean
'  myDearFriend! - www.mdf-xlpages.com
Dim vT As Date, HeuresFermeture As Date, HeuresTravail As Date, CumulHeuresNT As Date
    HeuresTravail = HorTMax - HorTMin
    HeuresFermeture = CDate("23:59:59") - HeuresTravail
    vT = T1
    Do Until DateDiff("d", vT, T2) < 1
        vT = DateAdd("d", 1, vT)
        If Weekday(vT, vbMonday) > 5 Then
            CumulHeuresNT = CumulHeuresNT + HeuresTravail
        End If
        CumulHeuresNT = CumulHeuresNT + HeuresFermeture
    Loop
    HorsDelai = T2 - T1 - CumulHeuresNT > DureeHMax
End Function

Cette fonction personnalisée est donc appelée depuis le Format Conditionnel des cellules souhaitées et retourne VRAI ou FAUX selon les critères voulus. Elle tient compte des weed-end puisque tu parles de jours Ouvrés.

La syntaxe d'utilisation est la suivante :

=HorsDelai( Cellule1 ; Cellule2 ; [DureeHMax] ; [HorTMin] : [HorTMax] )

- Cellule1 : référence de la cellule contenant la valeur Date/Heure de début
- Cellule2 : référence de la cellule contenant la valeur Date/Heure de fin
- DureeHMax : (facultatif) valeur horaire au format "00:00:00" représentant le délai maximum autorisé ("06:00:00" par défaut)
- HorTMin : (facultatif) valeur horaire au format "00:00:00" représentant l'horaire d'ouverture de l'entreprise("08:00:00" par défaut)
- HorTMin : (facultatif) valeur horaire au format "00:00:00" représentant l'horaire de fermeture de l'entreprise ("20:00:00" par défaut)

Dans ton cas, tu peux donc saisir simplement :
=HorsDelai(A2:B2)
puisque les valeurs adoptées par défaut sont celles que tu as proposées.

Dans ton exemple, j'ai appliqué cette façon de faire dans le Format conditionnel des cellules en colonne B (peut-être fallait-il le faire pour la colonne C ?)

Cordialement,