Forums XLPages

Excel & VBA Espace Débutants [résolu] Clignotement cellules selon conditions dans autres cellules

Clignotement cellules selon conditions dans autres cellules
#1
targa
Débutant XLPages

Inscription: 13/03/2012

Messages: 13

Système d'exploitation:
PC
Version Excel utilisée:
2003, 2007, 2010, 2013
Posté le : 13-03-2012 10h51

Bonjour,

 

Je suis nouveau sur votre site, et je suis en train de créer un fichier excel avec une base de cellules clignotantes, dont j'ai pu prendre l'exemple de code que vous mettiez à dispo sur votre fichier "mDF_CellulesEtAlertesClignotantes.xls".

 

J'ai essayé d'adapter, mais je rencontre quelques problèmes tout de même (n'étant pas un expert du code Visual Basic) car votre code fait référence à une cellule uniquement  est selon un résultat chiffré.

Pour palier à ce problème, j'ai dans une cellule au fond du tableau (cellule:F52), comptabilisé les cellules qui comporte la notion "Articles annulés", ainsi tous les textes de la colonne F (F5:F52), clignotent.

Est-il possible de faire référence à un texte, et non à un chiffre?

 

Mon cas:

J'ai un tableau dans lequel j'introduis des numéros d'articles, qui font références dans un onglet ou la base article se trouve, et dans cette base, il y a des articles annulés qui sont représentés dans une colonne avec un "x", ce "x" est reporté sur l'onglet "Liste de matériel" dans la colonne L. C'est grâce à ce "x" ensuite que je peux indiquer dans la colonne F si l'article est annulé ou pas (x ou 0).

 

Mon souhait:

Je souhaiterai que lorsque dans la colonne F, partout ou il vient "Article annulé", celles-ci clignotent.

Si je mets un autre texte manuellement il ne doit pas clignoter.

Car dans l'exemple joint, toutes les cases clignote, ce que je ne veux pas, que celles qui sont "Article annulé".

 

Pouvez-vous m'aider à modifier selon mon besoin, SVP, étant le créateur de ce code, je pense que cela ne peut être plus que très simple pour vous. J

 

En tous les cas, je peux vous dire que vos exemples mis à disposition sont très pratiques, et que votre site et très bien. UN GRAND MERCI !!

 

Vous trouverez joint à ce message, le fichier concerné.
En attente de votre réponse, je vous souhaite une excellente journée.

 

Salutations









Pièce jointe:
zip test_clignotement.zip   [ Taille: 33.25 Ko - Téléchargements: 802 ]
Hors Ligne
 Rapport   Haut 

Re: Clignotement cellules selon conditions dans autres cellules
#2
myDearFriend!
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1539

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 13-03-2012 19h17
Bonsoir targa, bienvenue sur XLpages.com

Tout d'abord, comme je le précise dans l'article « La méthode OnTime », l'utilisation d'une telle procédure doit rester dans un domaine ludique !
Je déconseille vivement l'utilisation que tu en fais sur un classeur à usage visiblement professionnel. Au minimum, il conviendrait de limiter la durée du clignotement (à une dizaine de clignotements par exemple, ça me paraîtrait plus raisonnable)...

Cela dit, pour répondre à ta demande et pour le fun , tu trouveras ton classeur modifié en pièce jointe.

J'ai utilisé le code VBA suivant :

DANS LE MODULE DE CODE DE L'OBJET THISWORKBOOK
Option Explicit
'---------------------------------------------------------------------------------------
' Auteur    : Didier FOURGEOT (myDearFriend!)
'             www.mdf-xlpages.com
' Date      : 13/03/2012
' Sujet     : Cellules et Alertes clignotantes
'---------------------------------------------------------------------------------------
Private Sub Workbook_Open()
    'Lance le clignotement  à l'ouverture si condition remplie
    Set PlageCible = getPlageCible
    If Not PlageCible Is Nothing Then
        Clign
    End If
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    'Interrompt le clignotement éventuel avant fermeture
    StopClign
End Sub

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    StopClign
    If Target.Count > 1 Then Exit Sub
    'Redéfinit la plage "clignotante"
    Set PlageCible = getPlageCible
    If Not PlageCible Is Nothing Then
        Clign
    End If
End Sub

DANS UN MODULE DE CODE STANDARD
Option Explicit
'---------------------------------------------------------------------------------------
' Auteur    : Didier FOURGEOT (myDearFriend!)
'             www.mdf-xlpages.com
' Date      : 13/03/2012
' Sujet     : Cellules et Alertes clignotantes
'---------------------------------------------------------------------------------------
Public PlageCible As Range
Dim Temps As Date

Public Sub Clign()
    'Programmation de l'évènement toutes les secondes
    Temps = Now + TimeValue("00:00:01")
    Application.OnTime Temps, "Clign"
    'Affiche l'alerte ou la fait disparaître (alternativement)
    With PlageCible
        .Font.ColorIndex = IIf(.Font.ColorIndex = 2, 3, 2)
    End With
End Sub

Public Sub StopClign()
    On Error Resume Next
    'Stoppe la gestion de l'évènement OnTime
    Application.OnTime Temps, "Clign", , False
    'Cache l'alerte
    PlageCible.Font.ColorIndex = 3
    On Error GoTo 0
End Sub

Public Function getPlageCible() As Range
Dim R As Range, Plage As Range
Dim Adr As String
    'Redéfinit la plage dite "clignotante"
    With Sheets("Liste de materiel").Columns(6)
        Set R = .Find("Article annulé", LookIn:=xlValues)
        If Not R Is Nothing Then
            Adr = R.Address
            Set Plage = R
            Do
                Set Plage = Union(Plage, R)
                Set R = .FindNext(R)
            Loop While Not R Is Nothing And R.Address <> Adr
        End If
    End With
    Set getPlageCible = Plage
End Function

En espérant avoir répondu à ta question (et si c'est le cas, voir au bas de ma signature STP)

Cordialement,
Pièce jointe:
zip PourTarga_test_clignotement.zip   [ Taille: 28.93 Ko - Téléchargements: 945 ]
Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
 Rapport   Haut 

Re: Clignotement cellules selon conditions dans autres cellules
#3
targa
Débutant XLPages

Inscription: 13/03/2012

Messages: 13

Système d'exploitation:
PC
Version Excel utilisée:
2003, 2007, 2010, 2013
Posté le : 14-03-2012 09h09
Bonjour Didier_mDF,

Ouhaaaa!!! Génial !!!

Merci, merci et encore merci, c'est tout à fait ce que je souhaitais.

En plus réponse rapide, je ne m'attendais pas à avoir une réponse si vite. C'est cool.

Autrement pour répondre à ta question, oui c'est pour un usage professionnel, le but étant de mettre l'attention au gens que l'article est annulé.
Alors pour suivre tes conseils, je vais limiter la durée du clignotement à une dizaine.

En tous cas un GRAND MERCI pour ton aide précieuse !

Excellente journée

Au plaisir de pouvoir faire aider aussi les autres si je peux.

Cordialement

P.S.: je clôture le sujet en même temps.
Hors Ligne
 Rapport   Haut 


Vous pouvez voir les sujets.
Vous ne pouvez pas débuter de nouveaux sujets.
Vous ne pouvez pas répondre aux contributions.
Vous ne pouvez pas éditer vos contributions.
Vous ne pouvez pas effacez vos contributions.
Vous ne pouvez pas ajouter de nouveaux sondages.
Vous ne pouvez pas voter en sondage.
Vous ne pouvez pas attacher des fichiers à vos contributions.
Vous ne pouvez pas poster sans approbation.

[Recherche avancée]


Qui consulte actuellement ce sujet ?   1 Utilisateur(s) anonymes