Forums XLPages

Excel & VBA Forum principal [résolu] Aide pour Userform

Aide pour Userform
#1
Slijack
Aspirant XLPages

Inscription: 22/11/2011
De Champeaux (Seine et Marne)

Messages: 21

Système d'exploitation:
PC
Version Excel utilisée:
2010
Posté le : 04-01-2012 02h16
bonsoir le forum !!!
j'ai modifier un code pour imprimer, mais ce que je ne sais pas faire c'est modifié l'Userform lié au bouton.
Mon problème est que je voudrai en face du nom de chaque onglet une quantité fixer par défaut a 1 et pouvoir la modifier si besoin
j'espère ne pas être trop brouillon dans ma demande, dans l'attente d'une réponse je vous remercie d'avance
PS. une pièce jointe du fichier modifier
Pièce jointe:
xls IMPRIMER.XLS   [ Taille: 49.00 Ko - Téléchargements: 459 ]
"Le plus lent à promettre est toujours le plus fidèle à tenir."
Hors Ligne
 Rapport   Haut 

Re: Aide pour Userform
#2
myDearFriend!
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1539

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 04-01-2012 15h34
Bonjour Slijack,

Tu trouveras en pièce jointe mon interprétation du problème.
L'ajout d'un contrôle SpinButton me semble un peu plus approprié que le TextBox mis par tes soins.

J'ai donc ajouté/modifié le code VBA suivant (dans le module de code du Userform) :

'*************************************************************************************
'Modification myDearFriend! (www.mDF-XLpages.com) - janvier 2012
Private Sub LbFeuilles_Change()
    With LbFeuilles
        .List(.ListIndex, 1) = IIf(.Selected(.ListIndex), 1, "")
        spbPages.Enabled = .Selected(.ListIndex)
    End With
    MajCptFeuilles
End Sub

Private Sub spbPages_SpinDown()
    With LbFeuilles
        .List(.ListIndex, 1) = Application.Max(Val(.List(.ListIndex, 1)) - 1, 1)
    End With
    MajCptFeuilles
End Sub

Private Sub spbPages_SpinUp()
    With LbFeuilles
        .List(.ListIndex, 1) = Val(.List(.ListIndex, 1)) + 1
    End With
    MajCptFeuilles
End Sub

Private Sub MajCptFeuilles()
Dim n As Integer
Dim S As Byte
    With LbFeuilles
        For S = 0 To .ListCount - 1
            If Not IsNull(.List(S, 1)) Then
                n = n + Val(.List(S, 1))
            End If
        Next S
    End With
    LblNombreFeuilles.Caption = "Nbre de Feuilles: " & n
End Sub

Private Sub CmdWsToutesSelection_Click()
    With LbFeuilles
        For I = 0 To .ListCount - 1
            .ListIndex = I
            If Not .Selected(I) Then .Selected(I) = True
        Next I
    End With
End Sub

Private Sub CmdWsAucuneSelection_Click()
    With LbFeuilles
        For I = 0 To .ListCount - 1
            .ListIndex = I
            .Selected(I) = False
        Next I
    End With
End Sub

Private Sub CmdImprimer_Click()
    With Application
        .ScreenUpdating = False
        For I = 0 To LbFeuilles.ListCount - 1
            If LbFeuilles.Selected(I) = True Then
                .StatusBar = "Impression: " & LbFeuilles.List(I)
                .DisplayAlerts = False
                Sheets(LbFeuilles.List(I)).PrintOut Copies:=Val(LbFeuilles.List(I, 1))
                .DisplayAlerts = True
            End If
        Next I
        .StatusBar = False
        .ScreenUpdating = True
    End With
    Unload Me
End Sub

En espérant que ça puisse te rendre service.

Cordialement,





Pièce jointe:
zip PourSlijackIMPRIMER.zip   [ Taille: 31.27 Ko - Téléchargements: 483 ]
Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
 Rapport   Haut 

Re: Aide pour Userform
#3
Slijack
Aspirant XLPages

Inscription: 22/11/2011
De Champeaux (Seine et Marne)

Messages: 21

Système d'exploitation:
PC
Version Excel utilisée:
2010
Posté le : 04-01-2012 21h02
Bonsoir Didier_mDF
Grand merci cela fonction bien il me reste a l'adapter à mon fichier.
En te souhaitant une bonne et heureuse année je te remercie encore pour ton aide
"Le plus lent à promettre est toujours le plus fidèle à tenir."
Hors Ligne
 Rapport   Haut 


Vous pouvez voir les sujets.
Vous ne pouvez pas débuter de nouveaux sujets.
Vous ne pouvez pas répondre aux contributions.
Vous ne pouvez pas éditer vos contributions.
Vous ne pouvez pas effacez vos contributions.
Vous ne pouvez pas ajouter de nouveaux sondages.
Vous ne pouvez pas voter en sondage.
Vous ne pouvez pas attacher des fichiers à vos contributions.
Vous ne pouvez pas poster sans approbation.

[Recherche avancée]


Qui consulte actuellement ce sujet ?   1 Utilisateur(s) anonymes