Utilisation de la fonction EQUIV avec des plages de données dynamiques
#1
Débutant XLPages

Inscription: 23/01/2011

Messages: 6

Système d'exploitation:
Mac
Version Excel utilisée:
Excel:mac 2004
Posté le : 16-02-2011 22h19
Bonjour,

Je suis dans une impasse, pour finir un projet j'ai besoin (me semble t-il) d'utiliser la fonction EQUIV mais je voudrais que l'argument "tableau_recherche" se modifie en fonction de la valeur d'une autre cellule.

Exemple :

    A  B  C  D  E  F  G  H  I  J  K  L
1  1  4  5  6  7  8                     x
2  2  5  6  7  8  9                     y
3  3  6  7  8  9  10
4  4  7  8  9
5  5  8  9
6  6  9

Je voudrais rechercher y dans la ligne 1 si x=1 (résultat : 6 avec EQUIV si y=8), dans la ligne 2 si x=2 (résultat : 5 avec EQUIV si y=8) ...

J'ai donné un exemple simple car mon fichier projet est un peu brouillon, en tout cas l'idée est là !

Autre question hors sujet mais je ne veux pas recréer un poste :
Est-ce qu'il existe une fonction SI avec plusieurs conditions ou est-on obligé d'imbriquer les fonctions SI comme je l'ai fait (pas très efficace en nombre d'étapes effectués par le CPU) :

=SI($J$5=5;RECHERCHEV($M$1;'Tableaux NSD'!$A$5:$X$48;$Q$1);SI($J$5=4;RECHERCHEV($M$1;'Tableaux NSD'!$A$54:$X$97;$Q$1);SI($J$5=3;RECHERCHEV($M$1;'Tableaux NSD'!$A$103:$X$146;$Q$1);SI($J$5=2;RECHERCHEV($M$1;'Tableaux NSD'!$A$152:$X$195;$Q$1);SI($J$5=1;RECHERCHEV($M$1;'Tableaux NSD'!$A$201:$X$244;$Q$1))))))

?

Merci d'avance pour votre aide

P.S. : je joins tout de même le fichier en question (le problème se pose en case V3 du premier onglet)
Pièce jointe:
xls Dose équivalente.xls   [ Taille: 76.00 Ko - Téléchargements: 513 ]
Hors Ligne
Rapport   Haut 

Re: Utilisation de la fonction EQUIV avec des plages de données dynamiques
#2
Accro XLPages

Inscription: 09/05/2007
De Courcelles-les-Montbéliard

Messages: 286

Système d'exploitation:
PC & Mac
Version Excel utilisée:
Mac 2004 - 2011, et PC 2003 - 2010
Posté le : 17-02-2011 01h03
Bonsoir Thorfin, Didier, le forum

Pour ta première question, je n'ai pas compris l'exemple ou les exemples que tu as donné.

Pour la question subsidiaire, il y a la fonction CHOISIR()

Extrait de l'aide :

Citation :

CHOISIR(no_index;valeur1;valeur2;…)

no_index     spécifie quel argument valeur doit être sélectionné. L'argument no_index doit être un nombre compris entre 1 et 29 ou une formule ou une référence à une cellule contenant un nombre compris entre 1 et 29.

  • Si la valeur de l'argument no_index est égale à 1, la fonction CHOISIR renvoie l'argument valeur1, si elle est égale à 2, elle renvoie l'argument valeur2, et ainsi de suite.
  • Si la valeur de l'argument no_index est inférieure à 1 ou supérieure au numéro de la dernière valeur de la liste, la fonction CHOISIR renvoie la valeur d'erreur #VALEUR!
  • Si la valeur de l'argument no_index est une fraction, il est ramené par troncature au nombre entier immédiatement inférieur avant d'être pris en compte.
valeur1, valeur2, ...     sont de 1 à 29 arguments de valeur parmi lesquels CHOISIR sélectionne une valeur ou une action à exécuter en fonction de l'argument no_index spécifié. Ces arguments peuvent être des nombres, des références de cellule, des noms définis, des formules, des fonctions ou du texte.


Tu pourrais écrire la formule de deux manières :

=CHOISIR($J$5;RECHERCHEV($M$1;'Tableaux NSD'!$A$201:$X$244;$Q$1);RECHERCHEV($M$1;'Tableaux NSD'!$A$152:$X$195;$Q$1);RECHERCHEV($M$1;'Tableaux NSD'!$A$103:$X$146;$Q$1);RECHERCHEV($M$1;'Tableaux NSD'!$A$54:$X$97;$Q$1);RECHERCHEV($M$1;'Tableaux NSD'!$A$5:$X$48;$Q$1))
moins orthodoxe
 
=RECHERCHEV($M$1;CHOISIR($J$5;'Tableaux NSD'!$A$201:$X$244;'Tableaux NSD'!$A$152:$X$195;'Tableaux NSD'!$A$103:$X$146;'Tableaux NSD'!$A$54:$X$97;'Tableaux NSD'!$A$5:$X$48);$Q$1)

Bonne nuit

@Jean-Marie




Edité par myDearFriend! le 18/02/2011 23:56:03
Hors Ligne
Rapport   Haut 

Re: Utilisation de la fonction EQUIV avec des plages de données dynamiques
#3
Débutant XLPages

Inscription: 23/01/2011

Messages: 6

Système d'exploitation:
Mac
Version Excel utilisée:
Excel:mac 2004
Posté le : 17-02-2011 20h43
Merci Jean-Marie, je ne connaissais pas cette fonction. C'est très pratique et permet de simplifier ma méthode lourd dingue.

Malheureusement mon problème principal reste entier, j'espère que quelqu'un m'apportera la solution.
Hors Ligne
Rapport   Haut 

Re: Utilisation de la fonction EQUIV avec des plages de données dynamiques
#4
Accro XLPages

Inscription: 09/05/2007
De Courcelles-les-Montbéliard

Messages: 286

Système d'exploitation:
PC & Mac
Version Excel utilisée:
Mac 2004 - 2011, et PC 2003 - 2010
Posté le : 17-02-2011 21h17
 Bonsoir

Soit plus clair dans l'énoncé de ton problème, c'est en général la meilleure façon d'avoir une réponse.

Peut-être une approche avec ce que j'avais compris, sans la mettre en pratique sur ton fichier, ne connaissant pas les valeurs X et Y

Sur la base de l'exemple de ton post =EQUIV(y;INDEX(A1:F6;x;0))

Particularité de la fonction INDEX, en spécifiant 0 à l'argument no_colonne, la fonction retourne toutes les valeurs contenues dans la ligne indiquée. Quand c'est no_ligne qui est égale à 0 se sont toutes les valeurs de la colonne indiquée qui sont retournées par la fonction.

@+Jean-Marie


Hors Ligne
Rapport   Haut 

Re: Utilisation de la fonction EQUIV avec des plages de données dynamiques
#5
Débutant XLPages

Inscription: 23/01/2011

Messages: 6

Système d'exploitation:
Mac
Version Excel utilisée:
Excel:mac 2004
Posté le : 20-02-2011 20h52
Merci Jean-Marie, c'est totalement la solution que je cherchais !
Hors Ligne
Rapport   Haut 


Vous pouvez voir les sujets.
Vous ne pouvez pas débuter de nouveaux sujets.
Vous ne pouvez pas répondre aux contributions.
Vous ne pouvez pas éditer vos contributions.
Vous ne pouvez pas effacez vos contributions.
Vous ne pouvez pas ajouter de nouveaux sondages.
Vous ne pouvez pas voter en sondage.
Vous ne pouvez pas attacher des fichiers à vos contributions.
Vous ne pouvez pas poster sans approbation.

[Recherche avancée]


Qui consulte actuellement ce sujet ?   1 Utilisateur(s) anonymes