Forums XLPages

Excel & VBA Espace Débutants [résolu] couleur

couleur
#1
milan34
Débutant XLPages

Inscription: 15/02/2010

Messages: 10

Système d'exploitation:
PC
Version Excel utilisée:
2007
Posté le : 15-02-2010 17h03
bjr
novice sur excel et sur ce forum j'espere que vous serai indulgent avec moi
sur un document excel j'aimerai additioner les cellules ayant un fond rouge et qui se trouve sur une meme ligne
qui pourra m'aider
suis sous excel 2007
mci
Hors Ligne
 Rapport   Haut 

Re: couleur
#2
myDearFriend!
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1539

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 16-02-2010 01h31
Bonsoir milan34 et bienvenue sur XLpages.com
Bonsoir le Forum,

Si j'ai bien compris la question... Voici une fonction personnalisée qui devrait répondre à ta demande si, et seulement si, la couleur n'est pas le résultat d'un format conditionnel :

VBA A COLLER DANS UN MODULE DE CODE STANDARD (ex: Module1) :
Option Explicit

Function SomCoul() As Double
'Somme des cellules avec fond de couleur Rouge et sur la même ligne que la cellule appelante
'myDearFriend! 16/02/2010
Dim Plage As Range, Cellule As Range, PlageCoul As Range, Target As Range
Dim Coul As Integer
    Application.Volatile
    Set Target = Application.Caller
    Coul = 3
    Set Plage = Target.EntireRow.Cells.SpecialCells(xlCellTypeConstants, 1)
    For Each Cellule In Plage
        If Cellule.Address <> Target.Address Then
            If Cellule.Interior.ColorIndex = Coul Then
                If PlageCoul Is Nothing Then Set PlageCoul = Cellule
                Set PlageCoul = Union(PlageCoul, Cellule)
            End If
        End If
    Next Cellule
    If Not PlageCoul Is Nothing Then
        SomCoul = Application.WorksheetFunction.Sum(PlageCoul)
    Else
        SomCoul = 0
    End If
End Function
Pour l'utiliser, il suffit de taper dans la cellule cible :
= SomCoul()
Cette fonction retourne la somme des cellules avec fond de couleur rouge et sur la même ligne que cette cellule cible.

Cela dit, d'une manière générale, il faut toujours éviter ce genre de traitement basé sur les couleurs (de cellule ou d'écriture). Pourquoi ? Tout simplement parce qu'il n'existe aucun évènement Excel qui réagit au changement des couleurs (aucune action exploitable). En d'autres mots, on ne peut "capter" un changement de couleur fait par l'utilisateur et donc, aucun recalcul de feuille ne sera effectué sur cette simple action... Attention donc : pour être sûr que la formule renvoie le bon résultat, forcer un recalcul de feuille serait une bonne habitude (via la touche F9 par exemple).

Cordialement,


Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
 Rapport   Haut 

Re: couleur
#3
milan34
Débutant XLPages

Inscription: 15/02/2010

Messages: 10

Système d'exploitation:
PC
Version Excel utilisée:
2007
Posté le : 17-02-2010 00h08
 mci
Hors Ligne
 Rapport   Haut 


Vous pouvez voir les sujets.
Vous ne pouvez pas débuter de nouveaux sujets.
Vous ne pouvez pas répondre aux contributions.
Vous ne pouvez pas éditer vos contributions.
Vous ne pouvez pas effacez vos contributions.
Vous ne pouvez pas ajouter de nouveaux sondages.
Vous ne pouvez pas voter en sondage.
Vous ne pouvez pas attacher des fichiers à vos contributions.
Vous ne pouvez pas poster sans approbation.

[Recherche avancée]


Qui consulte actuellement ce sujet ?   1 Utilisateur(s) anonymes