Suppression Parentheses et leur contenus
#1
Débutant XLPages

Inscription: 04/02/2022
De 56520 Guidel

Messages: 3

Système d'exploitation:
PC
Version Excel utilisée:
Office 2013 Pro 32 bits
Posté le : 04-02 11h35

Bonjour à la communaute,

Dans un premier temps ,je cherche à supprimer les parentheses et leurs contenus

Arrow Blue ( USA ) ( E1 )et que le nom soit sans espace ni au debut , ni à la fin

Ce qui donne : Arrow Blue

Desfois ily'a ( IRE ) ou ( GB ) etc....

Les parentheses se trouvent dans la colonne B et la colonne J

En vous remerciant par avance

Tres Cordialement

MRX78

Pièce jointe:
xlsx Nouveau Feuille de calcul Microsoft Excel.xlsx   [ Taille: 9.91 Ko - Téléchargements: 67 ]
Hors Ligne
Rapport   Haut 

Re: Suppression Parentheses et leur contenus
#2
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1521

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 04-02 18h02

Bonjour MRX78, bienvenue sur XLPages smiley

 

Tu ne précises pas vraiment.... par formule Excel ou par VBA ? 

 

Une proposition par formule Excel :

Par exemple, soit le texte "Paul Soto ( IRE )" en cellule B4.

La formule suivante devrait répondre à ta demande :

=SUPPRESPACE(SI(ESTERR(CHERCHE("(";B4));B4;GAUCHE(B4;CHERCHE("(";B4)-1)))

 

Une proposition par VBA :

Lancer la procédure "EpurerColBJ()" supprimera d'un coup, tous les contenus entre parenthèses en colonnes B et J de la feuille "Feuil1".

 

DANS UN MODULE DE CODE STANDARD (ex : Module1)

Option Explicit
'myDearFriend! www.mdf-xlpages.com

Sub EpurerColBJ()
Dim LMax As Long, L As Long
    With Sheets("Feuil1")
        LMax = .Cells(.Rows.Count, 1).End(xlUp).Row
        'Pour chaque ligne du tableau
        For L = 2 To LMax
            With .Cells(L, 2)       '2 = colonne B
                .Value = supprPth(.Value)
            End With
            With .Cells(L, 10)      '10 = colonne J
                .Value = supprPth(.Value)
            End With
        Next L
    End With
End Sub

Private Function supprPth(T As String) As String
Dim N As Byte
    N = InStr(T, "(")
    If N > 0 Then
        T = Left(T, N - 1)
    End If
    supprPth = Trim(T)
End Function

En espérant avoir répondu à ton besoin.

Bien cordialement,


Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
Rapport   Haut 

Re: Suppression Parentheses et leur contenus
#3
Débutant XLPages

Inscription: 04/02/2022
De 56520 Guidel

Messages: 3

Système d'exploitation:
PC
Version Excel utilisée:
Office 2013 Pro 32 bits
Posté le : 04-02 18h30

Bonjour My Dear Friend , 

 

Je te remercie d'avoir repondu

 

C'est plus tot du VBA genre macro , est ce que le code que tu as ecrit supprime les espaces

 

au debut et à la fin des noms?Qui se trouvent dans les colonnes suivantes.

 

Cela concerne la colonne B ( Nom du Cheval )

Cela concerne la colonne G ( Jockey )

Cela concerne la colonne I (Proprietaire )

Cela concerne la colonne J ( Entraineur )

 

Je te souhaite une bonne fin de journée , je vais tester le code pour les parentheses

 

Je te tiens au courant

Tres Cordialement

 

JeanMaurice

Hors Ligne
Rapport   Haut 

Re: Suppression Parentheses et leur contenus
#4
Débutant XLPages

Inscription: 04/02/2022
De 56520 Guidel

Messages: 3

Système d'exploitation:
PC
Version Excel utilisée:
Office 2013 Pro 32 bits
Posté le : 04-02 18h52

Rebonjour ,

 

J'ai testé c'est Super Nickel!!Un Grand Merci à toi

Apparement ça fait les espaces????

Bonne fin de journée

Encore un Grand Merci

Tres Cordialement 

Jean-Maurice alias MRX78 lol

Hors Ligne
Rapport   Haut 

Re: Suppression Parentheses et leur contenus
#5
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1521

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 05-02 12h25

Bonjour Jean-Maurice, le Forum,

 

Citation :

MRX78 a écrit :

... est ce que le code que tu as ecrit supprime les espaces au debut et à la fin des noms?Qui se trouvent dans les colonnes suivantes :

Cela concerne la colonne B ( Nom du Cheval )

Cela concerne la colonne G ( Jockey )

Cela concerne la colonne I (Proprietaire )

Cela concerne la colonne J ( Entraineur )

 

Oui, pour les colonnes B et J puisque c'était l'objet de ta demande initiale, mais non pour les colonnes G et I puisque tu n'en parlais pas... wink

 

Pour les colonnes B et J, c'est la fonction Trim() que j'ai utilisée. Elle supprime les espaces inutiles en début et fin d'expression texte, c'est son rôle, elle est faite pour ça!

Pour info, c'est un peu l'équivalent VBA de la fonction Excel de feuille de calcul "SUPPRESPACE()".

 

Pour ajouter ce même traitement (suppression des espaces inutiles seulement) aux colonnes G et I, tu pourrais modifier simplement la procédure VBA EpurerColBJ(), comme suit :

 

Sub EpurerColBJ()
Dim LMax As Long, L As Long
    With Sheets("Feuil1")
        LMax = .Cells(.Rows.Count, 1).End(xlUp).Row
        'Pour chaque ligne du tableau
        For L = 2 To LMax
            With .Cells(L, 2)       '2 = colonne B
                .Value = supprPth(.Value)
            End With
            With .Cells(L, 7)       '7 = colonne G
                .Value = Trim(.Value)
            End With
            With .Cells(L, 9)       '9 = colonne I
                .Value = Trim(.Value)
            End With
            With .Cells(L, 10)      '10 = colonne J
                .Value = supprPth(.Value)
            End With
        Next L
    End With
End Sub

Il te faut ajouter ce qui est indiqué en Jaune ci-dessus. Ne rien toucher au reste du code...

 

 

Si ça répond bien à ta demande, merci de mettre ce fil en "[Résolu]" (cf. ma signature ci-dessous).

Bien cordialement,

 


Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
Rapport   Haut 

Re: Suppression Parentheses et leur contenus
#6
Aspirant XLPages

Inscription: 26/10/2014
De ST QUENTIN 02

Messages: 30

Système d'exploitation:
PC
Version Excel utilisée:
2003
Posté le : 05-02 14h58

Bonjour le forum,

Bonjour MRX78, MyDearFriend

 

    Petite question : et si les valeurs entre parenthèses se situent au hasard de la cellule [ex : (C.f ) Not Now Dick ( Fr)] ou [Not Now (Ex) Dick ( Fr)] - Comment doit on procéder ? 

Merci et bon ouikand à toutes & à tous

@+ Ericcool

Hors Ligne
Rapport   Haut 

Re: Suppression Parentheses et leur contenus
#7
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1521

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 05-02 16h03

Bonjour Eric smiley,

 

Citation :

ericcool a écrit :

    Petite question : et si les valeurs entre parenthèses se situent au hasard de la cellule [ex : (C.f ) Not Now Dick ( Fr)] ou [Not Now (Ex) Dick ( Fr)] - Comment doit on procéder ? 

 

Arf, bonne question cher Eric !

 

Moi, je tenterais quelque chose comme ça :

Private Function supprPth(T As String) As String
Dim N As Byte, N2 As Byte
    N = InStr(T, "(")
    Do While N > 0
        N2 = InStr(N + 1, T, ")")
        If N2 > 0 Then
            T = Left(T, N - 1) & Mid(T, N2 + 1)
        End If
        N = InStr(T, "(")
    Loop
    T = Replace(T, "  ", " ")   'Eviter les éventuels double-espaces dans l'expression !
    supprPth = Trim(T)
End Function

 

Evidemment, je suppose que certains préfèreront faire appel aux expressions régulières ou autre du genre (et ils auront sûrement raison !), mais je continue de faire ça à l'ancienne pour ma part... wink

 

Bien cordialement,

 

 


Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
Rapport   Haut 

Re: Suppression Parentheses et leur contenus
#8
Aspirant XLPages

Inscription: 26/10/2014
De ST QUENTIN 02

Messages: 30

Système d'exploitation:
PC
Version Excel utilisée:
2003
Posté le : 05-02 16h28

Bonjour le forum

Re RMX78

   Merci Didier pour cette intervention. Comme cela, je suis sûr que cette fonction servira un jour ou l'autre à un membre ou une personne à la recherche de cette solution. Pour ma part, je mets de côté.

 

@RMX78 : n'oublie pas de mettre le sujet comme "Résolu" si tu juges que la solution t'a été apportée ==> Préfixe du sujet : AUCUN ou [Résolu].  

Bon ouikand 

@+ Eric 

Hors Ligne
Rapport   Haut 

Re: Suppression Parentheses et leur contenus
#9
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1521

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 05-02 16h42

Re,

 

Finalement, à bien y réfléchir Eric, voici une autre solution possible :

Private Function supprPth(T As String) As String
Dim vTab As Variant
Dim N As Byte
    vTab = Split(T, "(")
    T = vTab(0)
    For N = 1 To UBound(vTab)
        T = T & Split(vTab(N), ")")(1)
    Next N
    T = Replace(T, "  ", " ")   'Eviter les éventuels double-espaces dans l'expression !
    supprPth = Trim(T)
End Function

Je crois que je préfère cette solution là, qui me semble plus simple.

 

En tout cas, merci de ton passage Eric c (je suis toujours ravi de retrouver de vieux amis croisés sur d'autres forums, et en d'autres temps... De bons souvenirs !).

 

Bien cordialement,

 


Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
Rapport   Haut 

Re: Suppression Parentheses et leur contenus
#10
Aspirant XLPages

Inscription: 26/10/2014
De ST QUENTIN 02

Messages: 30

Système d'exploitation:
PC
Version Excel utilisée:
2003
Posté le : 05-02 18h00

Re le fil

 

  Merci Didier pour ce code plus condensé.

Oui, à moi aussi ça fait plaisir de croiser les anciens et de discuter un peu, cela prend peu de temps et c'est très agréable. Sur l'ex site, je croise encore quelque anciens et j'ai eu l'agréable surprise de voir notre ami @+Thierry apparaître lors du premier confinement.   

Bonne continuation à toi & aux tiens.

@micalement Eric 

Hors Ligne
Rapport   Haut 


Vous pouvez voir les sujets.
Vous ne pouvez pas débuter de nouveaux sujets.
Vous ne pouvez pas répondre aux contributions.
Vous ne pouvez pas éditer vos contributions.
Vous ne pouvez pas effacez vos contributions.
Vous ne pouvez pas ajouter de nouveaux sondages.
Vous ne pouvez pas voter en sondage.
Vous ne pouvez pas attacher des fichiers à vos contributions.
Vous ne pouvez pas poster sans approbation.

[Recherche avancée]


Qui consulte actuellement ce sujet ?   1 Utilisateur(s) anonymes