Forums XLPages

Excel & VBA Forum principal copier coller dans un même classeur

copier coller dans un même classeur
#1
ocealimer
Débutant XLPages

Inscription: 11/04/2013

Messages: 9

Système d'exploitation:
PC
Version Excel utilisée:
2003
Posté le : 12-04-2013 17h01
Bonjour,

voilà mon problème,

j'ai sur une feuille nommée "D.I" sur laquelle j'ai créer un bouton valider qui incrémenter mon numéro en B6, je voudrais que lorsque je clique sur ce même bouton les données de ma colonne B de B5 à B11 s'enrengistre dans mon tableau croisée dynamique nommée "rapport" sur une autre feuille. Mais cette fois ci que :
B5 s'enregistre sous la colonne a4
b6 s'enregistre sous la colonne b4
b7 s'enrehgistre sous la colonne c4 et cela jusqu'a b11 qui s'enregistre sur la colonne G4

J ai essayé plusieurs solution mais rien ne fonctionne, je plante complétement.

Merci pour votre aide

Hors Ligne
 Rapport   Haut 

Re: copier coller dans un même classeur
#2
ocealimer
Débutant XLPages

Inscription: 11/04/2013

Messages: 9

Système d'exploitation:
PC
Version Excel utilisée:
2003
Posté le : 12-04-2013 17h21
suite a ma demande d'aide je vous joins mon fichier

merci merci de me répondre
Hors Ligne
 Rapport   Haut 

automatiser la copie d'une colonne d'une feuille dans un tableau sur une autre
#3
ocealimer
Débutant XLPages

Inscription: 11/04/2013

Messages: 9

Système d'exploitation:
PC
Version Excel utilisée:
2003
Posté le : 12-04-2013 17h28
bonjour,

vraiment besoin d'aide, j'ai essayé plusieurs façon, mais lorsque je fais une copie avec vba de ma colonne B en feuille 1 celle ci ne se recopie pas du tout sur ma feuille 2 en ligne suivant le tableau
Hors Ligne
 Rapport   Haut 

Re: copier coller dans un même classeur
#4
Mth
Accro XLPages

Inscription: 23/05/2008
De La Varenne Saint-Hilaire

Messages: 356

Système d'exploitation:
PC
Version Excel utilisée:
2010
Posté le : 12-04-2013 22h34
Bonsoir ocealimer et bienvenue à toi, bonsoir à tous,

Malheureusement le fichier ne passe pas, il est peut-être trop lourd? As-tu essayé de le zipper?
Si non, pour joindre un fichier ce mode d'emploi pourra sans doute t'aider: Ajouter une pièce jointe

Pour le reste pourrais-tu veiller à rester sur le même fil, comme il s'agit du même sujet il n'est pas nécessaire de créer un autre sujet, il suffit de poursuivre sur celui-ci, sans quoi on s'y perd.

Très bonne soirée et à te relire avec ton fichier exemple qui nous aidera à comprendre ce que tu cherches à faire,

Bien à toi,

mth
Hors Ligne
 Rapport   Haut 

Re: copier coller dans un même classeur
#5
ocealimer
Débutant XLPages

Inscription: 11/04/2013

Messages: 9

Système d'exploitation:
PC
Version Excel utilisée:
2003
Posté le : 14-04-2013 05h38
bonsoir mtl,

merci pour ton message j'ai compressé mon dossier. Je le renvoie, encore merci pour votre accueil.
Hors Ligne
 Rapport   Haut 

Re: copier coller dans un même classeur
#6
Mth
Accro XLPages

Inscription: 23/05/2008
De La Varenne Saint-Hilaire

Messages: 356

Système d'exploitation:
PC
Version Excel utilisée:
2010
Posté le : 14-04-2013 11h19
Bonjour ocealimer, bonjour à tous,

Le fichier n'est toujours pas passé, peut-être fait-il plus de 80 Ko d'où le blocage ?

Très bonne journée et à bientôt,

mth
Hors Ligne
 Rapport   Haut 

Re: copier coller dans un même classeur
#7
ocealimer
Débutant XLPages

Inscription: 11/04/2013

Messages: 9

Système d'exploitation:
PC
Version Excel utilisée:
2003
Posté le : 14-04-2013 20h28
re bonjour MTH,

voilà j'espère que cette fois ci est la bonne.

MERCI BEAUCOUP
Pièce jointe:
zip Fiche_Intervention_SPAP_2013DEFINITIF modele.zip   [ Taille: 24.73 Ko - Téléchargements: 464 ]
Hors Ligne
 Rapport   Haut 

Re: copier coller dans un même classeur
#8
Mth
Accro XLPages

Inscription: 23/05/2008
De La Varenne Saint-Hilaire

Messages: 356

Système d'exploitation:
PC
Version Excel utilisée:
2010
Posté le : 14-04-2013 21h40
Bonsoir ocealimer, bonsoir à tous,

Un essai avec ce code, les commentaires sont en vert:
Option Explicit

Private Sub CommandButton1_Click()

Dim Derlig As Long
Dim Plage As Range

'Bloque le rafraichissement écran
Application.ScreenUpdating = False

'Définit la plage à copier:
With Sheets("DI")
    Set Plage = .Range("B5:B11")
End With

'Définit la première ligne vide de l'onglet Rapport
'*Puis copie la plage dans l'onglet Rapport
With Sheets("Rapport")
    Derlig = .Cells(Rows.Count, 1).End(xlUp).Row + 1
    Plage.Copy
    .Range("A" & Derlig).PasteSpecial Transpose:=True
End With

'Incrémente le n° intervention
With Sheets("DI")
    .Range("B6") = .Range("B6") + 1
End With

'Vide le presse papier
Application.CutCopyMode = False
   
'Rétablit le rafraichissement écran
Application.ScreenUpdating = True
End Sub
 

En espérant que cela puisse t'aider,

Très bonne soirée,

mth
Hors Ligne
 Rapport   Haut 

Re: copier coller dans un même classeur
#9
ocealimer
Débutant XLPages

Inscription: 11/04/2013

Messages: 9

Système d'exploitation:
PC
Version Excel utilisée:
2003
Posté le : 15-04-2013 19h07
bonjour MTH,

vraiment super merci merci beaucoup.

Une grosse épine du pied que tu m'enlèves,

Juste une dernière demande, je voudrais toujours avec le même bouton valider que ma feuille DI soit sauvegarder dans un dossier afin de conserver une copie.

de plus est il possible également qu'avec toujours mon bouton valider en rajoute l'impression de ma feuille DI.

Dans tout les cas, merci énormément

océalimer
Hors Ligne
 Rapport   Haut 

Re: copier coller dans un même classeur
#10
Mth
Accro XLPages

Inscription: 23/05/2008
De La Varenne Saint-Hilaire

Messages: 356

Système d'exploitation:
PC
Version Excel utilisée:
2010
Posté le : 16-04-2013 00h23
Bonsoir ocealimer, bonsoir le forum,

Pour imprimer, je te propose de rajouter ce code:
ExecuteExcel4Macro "PRINT(1,,,1,,,,,,,,2,,,TRUE,,FALSE)"
Il s'écrit tout seul avec l'enregistreur de macros, mais je te mets en PJ ce que j'ai trouvé sur les arguments de cette macro Excel4

Pour Sauvegarder ta feuille je te propose ceci, à adapter
Option Explicit
Sub SauvFeuille()

'Chemin = celui du fichier, à adapter
'Nom= "FicInterv_xxx" avec xxx= n° intervention, à adapter

Dim Chemin As String, NomFic As String

Chemin = ThisWorkbook.Path & ""
NomFic = Format(Sheets("DI").Range("B6"), "000000")

If NomFic <> "" Then
    'crée une copie de la feuille active
    ActiveSheet.Copy
   
    'Source Silkyroad, permet de retirer le code VBA dans le classeur sauvegardé
    With ActiveWorkbook.VBProject.VBComponents(ActiveSheet.CodeName).CodeModule
        .DeleteLines 1, .CountOfLines
    End With
   
    'Bloque les fenêtre d'alerte de l'application
    Application.DisplayAlerts = False
   
    'Format de fichier 56= Excel 97-2003
    ActiveWorkbook.SaveAs Chemin & NomFic, FileFormat:=56
    'Rétablit les fenêtres d'alerte
    Application.DisplayAlerts = True
   
    'Ferme le fichier Actif (qui est le fichier de sauvegarde)
    ActiveWorkbook.Close
End If


End Sub

et ... une petite correction, que tu trouveras à plusieurs endroits dans ton fichier joint:

ActiveSheet.Range("B5") = Date

ceci permet de figer la date du jour au lieu d'avoir une formule qui se recalcule à chaque fois

J'ai également mis ceci en fin de code, pour incrémenter mais aussi remettre les zone de saisie à blanc:

'Incrémente le n° intervention et remet le formulaire à blanc
With Sheets("DI")
    .Range("B6") = .Range("B6") + 1
    .Range("B7:B12").ClearContents
End With

Vois si cela peut t'aider,

Très bonne soirée,

mth

Pièce jointe:
zip Print MacroXL4.zip   [ Taille: 1.28 Ko - Téléchargements: 495 ]
zip Fiche_Intervention_SPAP_2013DEFINITIF modele.zip   [ Taille: 32.25 Ko - Téléchargements: 500 ]
Hors Ligne
 Rapport   Haut 


Vous pouvez voir les sujets.
Vous ne pouvez pas débuter de nouveaux sujets.
Vous ne pouvez pas répondre aux contributions.
Vous ne pouvez pas éditer vos contributions.
Vous ne pouvez pas effacez vos contributions.
Vous ne pouvez pas ajouter de nouveaux sondages.
Vous ne pouvez pas voter en sondage.
Vous ne pouvez pas attacher des fichiers à vos contributions.
Vous ne pouvez pas poster sans approbation.

[Recherche avancée]


Qui consulte actuellement ce sujet ?   1 Utilisateur(s) anonymes