Ventilation
#1
Débutant XLPages

Inscription: 04/11/2015
De Indre

Messages: 2

Système d'exploitation:
PC
Version Excel utilisée:
2010
Posté le : 04-11-2015 11h06

Bonjour,

 

Je viens demander votre aide pour le suivi d’un jeu, problème de ventilation.

Je désire ventiler chaque jour ou presque le tableau qui se trouve dans l’onglet « index » dans les onglets correspondants aux noms de chaque joueur et à la date indiquée en cliquant sur le bouton « Ventiler ».

Si possible en expliquant la façon de faire pour que je puisse ajouter éventuellement d’autres joueurs.

 

Je vous remercie de votre aide et vous souhaite une bonne journée.

Pièce jointe:
xlsm Essai.xlsm   [ Taille: 18.44 Ko - Téléchargements: 467 ]
Hors Ligne
Rapport   Haut 

Re: Ventilation
#2
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1539

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 04-11-2015 12h41

Bonjour catzzarts, bienvenue sur XLpages.com smiley

 

Tu trouveras en pièce jointe une façon de faire...

 

J'ai utilisé le code VBA suivant :

 

DANS UN MODULE DE CODE STANDARD (ex : Module1)

Option Explicit
'----------------------------------------------------------------------
' myDearFriend!  -  www.mdf-xlpages.com
' Novembre 2015
'----------------------------------------------------------------------
Sub Ventilation()
Dim vTab As Variant
Dim L As Long
    vTab = Sheets("Index").UsedRange.Value
    For L = 1 To UBound(vTab, 1)    'Pour chaque ligne d'Index
        If IsDate(vTab(L, 1)) Then  'Si date détectée en colonne 1
            Injection L, vTab       'Injecter les résultats
        End If
    Next L
    MsgBox "Ventilation des résultats terminée !"
End Sub

Private Sub Injection(L As Long, vTab As Variant)
Dim shCible As Worksheet
Dim R As Range
Dim C As Byte
    On Error Resume Next
    Set shCible = Sheets(vTab(L, 2))                'Onglet ? (si existe)
    On Error GoTo 0
    If shCible Is Nothing Then Exit Sub
    Set R = shCible.Columns(1).Find(vTab(L, 1))     'Date ? (si existe)
    If Not R Is Nothing Then
        'Injecter les résultats
        For C = 1 To 5
            R.Offset(0, C).Value = vTab(L, C + 2)
        Next C
    End If
End Sub

En théorie, il te faut simplement veiller au respect des points suivants :

  • Les noms des joueurs en onglet "Index" correspondent EXACTEMENT aux noms d'onglets joueurs.
  • Les dates en onglet "Index" sont également présentes dans ces onglets joueurs.

 

Pour l'ajout d'un joueur, il suffit simplement d'ajouter une ligne dans l'onglet "Index" et de créer son onglet correspondant.

Si les points ci-dessus sont respectés, la macro fera le reste...

 

En espérant que ça te dépanne.

Bien cordialement,

Pièce jointe:
xlsm PourCatzzarts.xlsm   [ Taille: 27.79 Ko - Téléchargements: 524 ]
Edité par myDearFriend! le 04/11/2015 16:05:21

Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
Rapport   Haut 

Re: Ventilation
#3
Débutant XLPages

Inscription: 04/11/2015
De Indre

Messages: 2

Système d'exploitation:
PC
Version Excel utilisée:
2010
Posté le : 04-11-2015 15h24

C’est génial, mes personnes âgées de la maison de retraite vous remercient infiniment, tout réaliser à la main était fastidieux. Avec l’explication c’est  encore mieux, je vais pouvoir progresser.

 

Encore merci  et bonne fin d’après-midi.

Hors Ligne
Rapport   Haut 


Vous pouvez voir les sujets.
Vous ne pouvez pas débuter de nouveaux sujets.
Vous ne pouvez pas répondre aux contributions.
Vous ne pouvez pas éditer vos contributions.
Vous ne pouvez pas effacez vos contributions.
Vous ne pouvez pas ajouter de nouveaux sondages.
Vous ne pouvez pas voter en sondage.
Vous ne pouvez pas attacher des fichiers à vos contributions.
Vous ne pouvez pas poster sans approbation.

[Recherche avancée]


Qui consulte actuellement ce sujet ?   1 Utilisateur(s) anonymes