Bonjour,

Pourriez-vous m'aider pour créer une macro permettant de :

- créer une nouvelle feuille dans un fichier excel, puis renommer cette même feuille.

En faisant plusieurs essais, le problème que je rencontre est le nom de la nouvelle feuille que je ne maitrise pas (voir mon essai ci-dessous)

Sub Macro2()
'
' Macro2 Macro
'

'
    Sheets.Add
    Sheets("Feuil3").Select
    Sheets("Feuil3").Name = "Nouvelle feuille"
End Sub

Je ne peux pas automatiser cette macro, car si je l'utilise plusieurs fois, le nom de la feuille ne sera pas toujours "Feuil3"

Merci de votre aide,

Olivier

Bonjour Basket,

Tout d'abord le code soumis présente quelques pièges :

Sub Macro2()

  Sheets.Add ' Ajoute bien une feuille mais ne permet pas de la saisir
  Sheets("Feuil3").Select ' L'utilisation de Select est à proscrire
                          ' et rien n'autorise à penser que la nouvelle
                          ' feuille a un nom d'onglet "Feuil3"
  Sheets("Feuil3").Name = "Nouvelle feuille"
    
End Sub

On pourra choisir l'une ou l'autre des procédures :

Public Sub AjouterFeuille()

  Static I As Long ' Une variable statique garde sa valeur à chaque appel
  Dim Feuille As Worksheet ' Une référence à la feuille nouvellement créée
  
  I = I + 1     ' L'index est augmenté

  Set Feuille = ThisWorkbook.Worksheets.Add ' La référence est posée
  
  Feuille.Name = "Nouvelle feuille " & I ' Le nom d'onglet de la nouvelle feuille est posé.
      
End Sub

Public Sub AjouterFeuilleAvecNom(Nom As String)

  Dim Feuille As Worksheet
  
  On Error GoTo AjouterFeuilleAvecNom_Error
  
  Set Feuille = ThisWorkbook.Worksheets.Add ' La référence est posée
  Feuille.Name = Nom ' Le nom d'onglet de la nouvelle feuille est posé.
    
  
  On Error GoTo 0
  Exit Sub

AjouterFeuilleAvecNom_Error:
  Select Case Err.Number
    Case 1004
      If Err.Description Like "*feuille*" Then
        
        MsgBox "Une feuille " & Chr(34) & Nom & Chr(34) & " existe déjà." & vbCrLf & _
               "Veuillez choisir un nom de feuille unique.", vbInformation, "Ajout de feuille"
               
      End If
      
  End Select
  
End Sub

À tester de ton côté.

Cordialement,

Guy

Merci Guy pour ton retour.

Ma réponse est très tardive, je m'en excuse, j'ai été absent un long moment.

Merci

Cdlt

Olivier