Bonjour zorbrax, le Forum,

Ce code fait parfaitement son travail (y compris les 3 dernières lignes !).

Je résume le déroulement de ton code :

1. Tu copies une feuille de calcul (ce qui crée automatiquement un nouveau classeur).
2. Tu envoies ce nouveau classeur par mail.
3. Tu fermes ensuite ce nouveau classeur.

J'ai testé et ton code fait correctement son travail, sans problème.

Je me permets simplement de te proposer ces quelques lignes à peine simplifiées, en lieu et place (ça ne change rien au déroulement attendu) :

Sub Envoi()
Dim Dest As String, Sujet As String
    Sheets("Feuil4").Copy 'Saisir le nom exact la feuille à copier
    Dest = "xxxxxx.xxx@xxx.xx" 'Saisir l'adresse mail
    Sujet = "Envoi Test" 'mettre le sujet de l'envoi
    With ActiveWorkbook
       .SendMail Dest, Sujet, True
       .Close SaveChanges:=False    'ferme LA COPIE de la feuille
    End With
End Sub

Bien cordialement,

Bonjour FabriceR,

Tu as tout compris ! C'est bien ça.

Bien cordialement,

OK,  alors je clôture ce sujet.

Merci de le faire par toi même la prochaine fois (voir lien dans ma signature).

Bien cordialement,

Bonsoir country37, bienvenue sur mDF XLpages.com

Je te propose la mise en place d'un format conditionnel comme suit :

1. Tu sélectionnes la plage entière : $E$6:$H$34
2. Dans le Ruban Excel Accueil / Mise en forme conditionnelle / Nouvelle règle
3. Tu choisis "Utiliser une formule pour déterminer pour quelles cellules le format sera appliqué"
4. Dans la zone de saisie en dessous, tu colles (ou saisis) la formule suivante :

   =SI($E6<>"";CHERCHE($E6;"RTT, CP, Intempéries, Absent");0)>0

5. En dessous toujours, tu définis le Format souhaité (Couleur de police Rouge).
6. Et tu valides le tout.

En pièce jointe, ton classeur exemple modifié en conséquence.

En espérant t'avoir dépanné.

Bien cordialement,

Bonjour FabriceR, le Forum,

OK, mauvaise interprétation de ma part concernant le nom des CSV.

Par ailleurs, tu n'as finalement pas besoin de joindre un exemplaire de fichier CSV et je te propose la procédure suivante pour Test :

Sub Import_Data_Click()
Dim wbCSV   As Workbook
Dim wsMstr  As Worksheet
Dim vTabCSV() As String
Dim fPath As String, fCSV As String, FilesInPath As String
Dim NextCol As Long, nCSVmax As Long, nCSV As Long

    Set wsMstr = ThisWorkbook.Sheets("Data")
    fPath = Worksheets("Menu").Cells(4, 1).Value   'path to CSV files
    
    'Add a backslash at the end if the user forget it
    If Right(fPath, 1) <> "" Then
        fPath = fPath & ""
    End If
    
    'If there are no CSV files in the folder exit the sub
    FilesInPath = Dir(fPath & "*.csv")
    If FilesInPath = "" Then
        MsgBox "No files found"
        Exit Sub
    End If
    
    If MsgBox("Clear the existing Data sheet before importing?", _
            vbYesNo, "Clear Database?") = vbYes Then
        wsMstr.UsedRange.ClearContents
        NextCol = 1
    Else
        NextCol = wsMstr.Cells(6, Columns.Count).End(xlToLeft).Column + 2
    End If
    
    Application.ScreenUpdating = False  'speed up macro
    
    'start the CSV file listing (sort by number)
    fCSV = Dir(fPath & "*.csv")
    Do
        nCSV = Val(fCSV)
        If nCSV > 0 Then
            nCSVmax = Application.Max(nCSVmax, nCSV)
            ReDim Preserve vTabCSV(1 To nCSVmax)
            vTabCSV(nCSV) = fCSV
        End If
        fCSV = Dir
    Loop Until fCSV = ""
    
    'Store CSV datas
    For nCSV = 1 To UBound(vTabCSV, 1)
        If vTabCSV(nCSV) <> "" Then
            'open a CSV file
              Set wbCSV = Workbooks.Open(fPath & vTabCSV(nCSV))
            'copy data into master sheet and close source file
              wbCSV.Sheets(1).UsedRange.Copy wsMstr.Cells(3, NextCol)
              wbCSV.Close False
              NextCol = wsMstr.Cells(6, Columns.Count).End(xlToLeft).Column + 1
        End If
    Next nCSV
    
    Sheets("Menu").Select
    Application.ScreenUpdating = True
    MsgBox "Data Import completed"
End Sub

En espérant que ça puisse répondre à ton problème...

Bien cordialement,

Bonsoir FabriceR,

Je pense que tu ne nous as pas tout dit sur les noms exactes de ces fichiers CSV.

Ils sont numérotés OK, mais, à la vue de ton code j'ai bien l'impression qu'il n'y a pas qu'un numéro et ça me semble important là.

Peux tu nous citer les noms exactes, disons pour les 12 premiers...

Ensuite, si ce n'est pas confidentiel, tu peux aussi joindre un exemplaire d'un  CSV en question (zippé pour le poster ici).

Bien cordialement,

Bonjour ploz, bienvenue sur XLpages.

Il me semble que Julien35000  attend un fichier de ta part pour donner réponse à ton problème dans cet autre forum : http://forum.excel-pratique.com/excel ... eu-special-t73388-10.html

Ça serait dommage de négliger les efforts qu'il consent pour t'aider.

Bien cordialement,

Bonjour Vanerdi, bienvenue sur XLpages

Pas simple de te répondre car tu ne donnes pas beaucoup de détails sur ce que veux obtenir exactement et par quel moyen....

Cela dit, comme ça, le plus simple à mettre en œuvre reste le Copier-Coller « avec Liaison » :

• Tu ouvres d'abord tes 2 classeurs en simultané
• Tu sélectionnes la cellule (ou la plage de cellules) souhaitée dans ton classeur « Travail »
• Tu fais un « Copier »
• Tu sélectionnes ensuite la cellule (ou plage de cellules) cible du classeur « Recevoir »
• Tu fais un clic droit et tu choisis simplement « Coller avec liaison » dans le menu contextuel.

Tu peux ensuite enregistrer et refermer tes 2 classeurs.

Dorénavant, et sur ces cellules concernées, ce que tu modifieras dans le classeur source « Travail » sera reproduit automatiquement dans le classeur cible « Recevoir » sans avoir à l'ouvrir en même temps.

En espérant avoir répondu à ton besoin.

Bien cordialement,

Bonsoir naka1oneshot, le Forum,

Je te propose le code VBA suivant, actionné par un bouton dans la feuille "CLIENT" :

DANS UN MODULE DE CODE STANDARD (Ex : Module1)

Option Explicit
'---------------------------------------------------------------------
' Auteur    : Didier FOURGEOT (myDearFriend!)
' Site      : www.mdf-xlpages.com
' Date      : Janvier 2016
'---------------------------------------------------------------------
Sub Repartition()
Dim TabTemp As Variant
Dim FCible As Worksheet
Dim NomBateau$
Dim L As Long, LignCible As Long
Dim C As Integer
    'Mémorise le tableau de données "CLIENT" dans une variable TabTemp
    With Sheets("CLIENT")
        'N° dernière ligne du tableau ?
        L = DernLign(Sheets("CLIENT"), 1)
        'Le tableau commence à la ligne 9 et se termine en colonne 9
        TabTemp = .Range(.Cells(9, 1), .Cells(L, 9)).Value
    End With
    'Pour chaque ligne du tableau
    For L = 1 To UBound(TabTemp, 1)
        NomBateau = TabTemp(L, 7)
        On Error Resume Next
        Set FCible = Sheets(NomBateau)
        On Error GoTo 0
        'La feuille existe ?
        If Not FCible Is Nothing Then
            'Les données commencent ligne 16, colonnes 8 à 15
            With FCible
                'Première ligne disponible dans la feuille Cible
                LignCible = DernLign(FCible, 8) + 1
                'On recopie toutes les colonnes sauf la 7e
                For C = 1 To 9
                    Select Case C
                    Case 1 To 6
                        .Cells(LignCible, C + 7).Value = TabTemp(L, C)
                    Case 8 To 9
                        .Cells(LignCible, C + 6).Value = TabTemp(L, C)
                    End Select
                Next C
            End With
            Set FCible = Nothing
        End If
    Next L
    MsgBox "Répartition réalisée. OK !"
End Sub

Private Function DernLign(F As Worksheet, colDepart As Integer) As Long
    With F
        DernLign = .Cells(.Rows.Count, colDepart).End(xlUp).Row
    End With
End Function

En pièce jointe, ton fichier adapté en conséquence.

En espérant t'avoir dépanné...

Bien cordialement,

Merci mon cher ami Guy !

A mon tour de vous souhaiter, à toutes et tous, mes

Meilleurs Vœux pour cette nouvelle Année !

Bien cordialement,