Rapport de message :*
 

Re: Creer une synthèse

Titre du sujet : Re: Creer une synthèse
par JeanMarie le 03/10/2011 21:04:27

Bonsoir Turfman, Myta, Didier, le forum

Une solution en formule, mais pas simple à expliquer.

On peut envisager la résolution de ton problème à l'aide d'un tableau intermédiaire.

J'inscris dans la plage Q4:Q19 les valeurs allant de 1 à 16, (16 étant la valeur maxi contenue dans ton tableau ABCDE). La colonne suivante va calculer le nombre de points pour chaque valeurs contenues dans le 1er rang, avec la formule ci-dessous
en R4, et un glisser vers le bas
=NB.SI(B$4:F$4;Q4)*3
La colonne suivante calculant le nombre de points du 2ème rang. Formule en R4, puis glisser vers le bas
=NB.SI(B$5:F$5;Q4)*2
La clonne suivant le nombre de point, je te laisse trouver la formule (toujours avec NB.SI).

Dans la colonne suivante, on additionne le tout.

Maintenant il faut pouvoir connaître la valeur ayant le plus de points et aussi les suivantes, pour cela il y a dans Excel une fonction qui se nomme GRANDE.VALEUR(...:...;x).
La formule GRANDE.VALEUR(U4:U19;1) retournera 9, il reste une formule pour résoudre ton problème, trouver le N° associé au nombre de point, simple !
Non, pour la simple raison que tu as des points qui se répétent plusieurs fois.


Il faut rajouter un "détrompeur" aux valeurs des points calculés. On peut rajouter une partie décimale à chauqe nombre de points. C'est la partie décimale représentera dans le n° de la valeur.


Donc en U4 tu vas avoir la formule
=R4+S4+T4+Q4/100
Mais voilà, tu classes les valeurs équivalentes en nombre de points (exemple 4 puis 5)
il faut donc encore trucquer, puisque que GRANDE.VALEUR classe à l'inverse de l'ordre que tu souhaites.
=R4+S4+T4+((17-Q4)/100)

A ce niveau il suffit d'écarter la partie entière ou la partie décimale en fonction de ce que tu veux obtenir.
=17-MOD(GRANDE.VALEUR(U4:U19;Q4);1)*100
=ENT(GRANDE.VALEUR(U4:U19;Q4))


Il y a une autre solution, en supprimant le tableau intermédiaire (en Q:U), Mais en utilisant le même principe du tableau ordonné des valeurs et du total de points.
Le problème est de constistuer un tableau "en mémoire" ayant la même représentation.
Je ne vais pas trop rentrer dans les détails, ne connaissant pas ton niveau. 
Pour créer ce tableau "en mémoire", il faut ajouter à ton classeur un nom, (sous office 2003 menu Insertion/Nom/Définir...) dans la boîte de dialogue, dans le champ en haut, tu indiques NbPoints (par exemple), puis dans le champ en dessous de "fait référence à :" tu colles la formule ci-dessous, et tu valides
=FREQUENCE(Feuil1!$B$4:$F$4;LIGNE(Feuil1!$1:$15))*3+FREQUENCE(Feuil1!$B$5:$F$5;LIGNE(Feuil1!$1:$15))*2+FREQUENCE(Feuil1!$B$6:$F$6;LIGNE(Feuil1!$1:$15))+((17-LIGNE(Feuil1!$1:$16))/100)
Voilà tu viens de créer le tableau.

Tu rajoutes dans la plage H4:H19 les valeurs 1 à 16, puis les formules ci dessous dans les cellules adjacentes et un glisser vers le bas.
=17-MOD(GRANDE.VALEUR(NbPoints;H4);1)*100
=ENT(GRANDE.VALEUR(NbPoints;H4))
Voilà tu as ta synthèse. Bon courage

Pour finir une mise en forme, pour la beauté du tableau.

@+Jean-Marie