Titre du sujet : Re: Afficher/Maquer des colonnes par myDearFriend! le 21/11/2009 21:02:50
Bonsoir lours, bienvenue sur XLpages.com
Bonsoir Mth, le Forum,
En pièce jointe, une autre proposition qui te conviendra peut-être...
J'ai utilisé le code suivant :
Option Explicit
Private Sub UserForm_Initialize()
Dim Cell As Range
With ListboxF
.ColumnCount = 2 '2 colonnes dans la ListBox
.ColumnWidths = ";0" 'dont la deuxième cachée
.BoundColumn = 2 'La propriété "Value" renverra la valeur de la colonne cachée
For Each Cell In Rows(24).SpecialCells(xlCellTypeConstants, 23)
.AddItem Cell.Text '1ère colonne : les prénoms
.List(.ListCount - 1, 1) = Cell.Column '2ème colonne : les numéros de colonnes correspondantes
Next Cell
End With
End Sub
Private Sub ListBoxF_Click()
BoutonOnOff.Caption = IIf(Columns(Val(ListboxF.Value)).Hidden, "Afficher", "Masquer")
End Sub
Private Sub ListBoxF_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
BoutonOnOff_Click
End Sub
Private Sub BoutonOnOff_Click()
'Masque ou affiche la colonne cible et la colonne à sa droite
With Columns(Val(ListboxF.Value))
.Hidden = Not .Hidden
.Offset(0, 1).Hidden = Not .Offset(0, 1).Hidden
End With
ListBoxF_Click
ActiveWindow.ScrollColumn = 1
End Sub
Private Sub BoutQuitte_Click()
Unload Me
End Sub
Cordialement,
|