Rapport de message :*
 

Re: raccourci par macro

Titre du sujet : Re: raccourci par macro
par myDearFriend! le 27/02/2008 18:29:08

Bonsoir carioca, JCGL, le Forum,

En premier lieu, je confirme ce que dit JCGL, il est toujours préférable de donner au moins le bout de code utilisé pour faciliter les réponses (voire de joindre un exemple).

Espérant avoir quand même compris ta demande, je te propose donc la solution suivante :
Tout d'abord, en se basant sur la solution donnée ici : FAQ - [VBA] Comment créer un raccourci du classeur actif sur le bureau Windows ?.

Pour pointer sur l'icône sauvegardée sur ton disque dur :

DANS UN MODULE DE CODE STANDARD
Option Explicit

Sub CreerRaccourci()
'myDearFriend!  -  www.mdf-xlpages.com
Dim Raccourci As Object
    With ActiveWorkbook
        'Vérifie l'existence d'un chemin pour le classeur
        If .Name <> .FullName Then
            'Défini le raccourci
            With CreateObject("WScript.Shell")
                Set Raccourci = .CreateShortcut(.SpecialFolders("Desktop") _
                    & "\" & ActiveWorkbook.Name & ".lnk")
            End With
            With Raccourci
                'Affecte l'icône (chemin à adapter)
                .IconLocation = "C:\MonIcone.ico"
                'Crée le raccourci sur le bureau Windows
                .TargetPath = ActiveWorkbook.FullName
                .Save
            End With
        Else
            MsgBox "Sauvegardez déjà le classeur sur le DD et recommencez..."
        End If
    End With
End Sub


Par ailleurs, si la présente solution te convient, je t'invite à solder ta question sur XLD ICI, afin d'éviter que d'autres planchent sur ton problème pour rien... (merci aussi d'éviter les multiposts à l'avenir, ce n'est pas forcément bien apprécié des intervenants).

Cordialement,

EDITION :
Code VBA rectifié suite à la remarque judicieuse de Carioca.