Bonjour à tous,

Je souhaite comparer le texte contenu dans 2 colonnes. Si une partie de du texte d'une colonne est présent dans la cellule voisine de la colonne 2 - je souhaite afficher OK dans la troisième colonne - le cas échéant je souhaite faire apparaitre NOK. Exemple :

1) cellule colonne 1 [herve mari] / cellule voisine colonne 2 [mari] => affichage colonne 3 : OK

Est ce possible ?

Merci d'avance de votre aide.

Bonjour Hervec, Didier, le forum

Différentes possibilités :

1) Avec la fonction TROUVE

Fonction de la catégorie "TEXTE"

=SI(ESTERR(TROUVE(B1;A1));"";"OK")

Cette fonction recherche le texte du 1er argument dans la donnée du 2ème argument, et en retourne la position de la chaîne cherché, si la chaîne n'est pas présente un message d'erreur est retourné.

A noter, cette fonction reste la "case", c'est-à-dire les majuscules.

2) Avec la fonction CHERCHE

Fonction de la catégorie "TEXTE"

=SI(ESTERREUR(CHERCHE(B2;A2));"";"OK")

La fonction Cherche fait la même recherche mais celle-ci se moque des majuscules.

3) Avec la fonction NB.SI

Fonction de la catégorie "statistique"

On détourne la fonctionnalité de cette fonction qui est de déterminer le nombre d'occurence d'un texte (2ème argument) dans une plage de cellules (1er argument)

=CHOISIR(NB.SI(A3;"*"&B3&"*")+1;"";"OK")

Pour savoir si un texte est contenu dans une cellule avec la fonction NB.SI il faut rajouter ce que l'on appelle un caractère générique. Excel dispose de deux caractères génériques le "*" et le "?".

Définition des Caractères génériques : Un caractère générique est un caractère du clavier que vous pouvez utiliser pour représenter un ou plusieurs caractères. Par exemple, l’astérisque (*) représente généralement un ou plusieurs caractères, et le point d’interrogation (?) représente généralement un seul caractère.

J'ai remplacer la fonction SI par CHOISIR, lol

4) la fonction EQUIV

Fonction de la catégorie "Recherche et Matrice"

La fonction première de cette fonction est de recherche un élément (1er argument) dans une plage de cellules.

=SIERREUR(EQUIV("*"&B4&"*";B4;0);"")

On doit utiliser le caractères générique "*".

La fonction retourne un message d'erreur "N/A#" si le texte recherché n'est pas présent dans la cellule. Depuis Office 2007, excel dispose d'une nouvelle fonction SIERREUR que j'ai utilisé pour la formule. lol

Attention Excel limite les longueurs de texte à rechercher à 255 caractères.

Voilà différentes possibilités. 

@+Jean-Marie

Super Merci Jean-Marie pour ce retour complet et toutes ces solutions ! Nickel ca fonctionne !