Forums XLPages

Excel & VBA Forum principal [résolu] clignoter dans un TextBox

clignoter dans un TextBox
#1
flamel
Débutant XLPages

Inscription: 12/04/2010

Messages: 2

Système d'exploitation:
PC & Mac
Version Excel utilisée:
2003
Posté le : 12-04-2010 14h47
Bonjour,

Je viens de découvrir ce forum et tous les téléchargements qui sont extrêmement intéressants. 
Je souhaiterais faire clignoter un TextBox ou son texte dans un UserForm.
Je n'y arrive pas avec le code proposé pour les feuilles Excel et qui marche très bien.
Merci si vous pouvez m'aider.
Hors Ligne
 Rapport   Haut 

Re: clignoter dans un TextBox
#2
myDearFriend!
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1539

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 12-04-2010 19h41
Bonsoir flamel et bienvenue sur XLpages.com
Bonsoir le Forum,

Tu trouveras en pièce jointe une tentative de réponse à ta question...

J'ai repris le code du classeur exemple en téléchargement Cellules et Alertes clignotantes, basé sur la méthode OnTime (voir l'article détaillé).

Le code VBA modifié est devenu le suivant pour cet exemple avec TextBox :

DANS LE MODULE DE CODE DU USERFORM
Option Explicit
' myDearFriend!  -  www.mdf-xlpages.com

Private Sub btnGo_Click()
    If IsEmpty(Temps) Then
        Clign
    End If
End Sub

Private Sub btnStop_Click()
    StopClign
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    StopClign
End Sub

DANS UN MODULE DE CODE STANDARD
Option Explicit
' myDearFriend!  -  www.mdf-xlpages.com

'En déclarant cette variable Temps en "public", elle devient accessible partout dans le projet
Public Temps As Variant

Sub AffichUsf()
    UserForm1.Show
End Sub

Sub Clign()
    'Programmation de l'évènement toutes les secondes
    Temps = Now + TimeValue("00:00:01")
    Application.OnTime Temps, "Clign"
    'Affiche l'alerte ou la fait disparaître (alternativement)
    With UserForm1.LeTextBox
        .BackStyle = IIf(.BackStyle = fmBackStyleOpaque, fmBackStyleTransparent, fmBackStyleOpaque)
    End With
End Sub

Sub StopClign()
    On Error Resume Next
    'Stoppe la gestion de l'évènement OnTime
    Application.OnTime Temps, "Clign", , False
    On Error GoTo 0
    'Cache l'alerte
    UserForm1.LeTextBox.BackStyle = fmBackStyleOpaque
    Temps = Empty
End Sub

Ne sachant pas exactement ce que tu comptes faire (merci au passage de présenter un exemple de ce que tu souhaites la prochaine fois), j'ai joué sur la propriété Backstyle du TextBox pour afficher ou masquer alernativement un message d'alerte en transparence.

En espérant t'avoir dépanné.

Cordialement,
Pièce jointe:
zip PourFlamel.zip   [ Taille: 8.61 Ko - Téléchargements: 1644 ]
Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
 Rapport   Haut 

Re: clignoter dans un TextBox
#3
flamel
Débutant XLPages

Inscription: 12/04/2010

Messages: 2

Système d'exploitation:
PC & Mac
Version Excel utilisée:
2003
Posté le : 19-04-2010 08h22
Bonjour,

Merci myDearFriend. C'est exactement ce que je voulais.
Encore merci.

flamel
Hors Ligne
 Rapport   Haut 


Vous pouvez voir les sujets.
Vous ne pouvez pas débuter de nouveaux sujets.
Vous ne pouvez pas répondre aux contributions.
Vous ne pouvez pas éditer vos contributions.
Vous ne pouvez pas effacez vos contributions.
Vous ne pouvez pas ajouter de nouveaux sondages.
Vous ne pouvez pas voter en sondage.
Vous ne pouvez pas attacher des fichiers à vos contributions.
Vous ne pouvez pas poster sans approbation.

[Recherche avancée]


Qui consulte actuellement ce sujet ?   1 Utilisateur(s) anonymes