gestion de l'insertion de lignes et de la saisie sur ces lignes
#1
Régulier XLPages

Inscription: 05/10/2009
De 33210-Gironde

Messages: 49

Système d'exploitation:
PC
Version Excel utilisée:
2007
Posté le : 18-10-2009 00h01
Bonsoir le Forum,

Je désire arriver à gérer des insertions "ciblées" de lignes et de contrôler si leur saisie a été effectuée avant tri et sauvegarde par boutons et macros, et ce dans des "zones définies" d'un tableau.
Actuellement, les macros de base fonctionnent, mais je vois bien qu'il faut y ajouter du code, et là .....

Je joins un exemple, qui inclus le texte ci-dessous.

Mot de passe protection de la feuille : cars      (la feuille est verrouillée.)
zone  déverrouillée : "zone_de_saisie"
zone de tri : "liste_tri"

A chaque insertion de ligne :
Les formules présentes dans les colonnes A & B doivent être reconduites automatiquement dans la ou les nouvelle(s) ligne(s)

L'insertion (se fait en L10) est commandée par un bouton "Insertion de lignes".
L'action peut être répétitive (plusieurs lignes)
La fonction "annuler" (symbole avec la petite flèche recourbée) du menu doit rester disponible pour le cas d'erreur de choix du nombre de lignes à insérer. (Elle est grisée quand on verrouille la feuille)

La saisie est obligatoire : répertoire du modèle (col C), et 1 lieu au moins, (col de D à H) sinon : pas de tri possible. (bouton inactif ou grisé)
Le bouton "tri des répertoires" doit permettre "après saisie obligatoire" : le tri de la zone "liste_tri",  (tri personalisé par la colonne C, trié sur valeurs, ordre de A-Z).

S'il n'y a pas eu de saisie sur toutes les nouvelles lignes, l'action sur le bouton de tri génère l'affichage du message " saisie à effectuer ou suppression de la ligne vide".

Validation de "saisie à effectuer" redonne le focus à la ligne vide
Validation de "supprimer la ligne" supprime cette ligne vide

Une boîte de dialogue demandant de "sauvegarder sous" doit être proposé après l'action de ce tri.

Nb.
La fonction du module1 nécessite pour être rafraichie d'effectuer la sélection des cellules à rafraîchir, et de faire "F2+CRTLEntrée". Comment faire pour qu'elle soit rafraîchie automatiquement à chaque saisie d'un lien hypertexte ? (pas urgent)

Merci.
Ce texte est également dans la feuille de l'exemple.

Gmarin.





Pièce jointe:
zip model1.zip   [ Taille: 25.82 Ko - Téléchargements: 581 ]
Hors Ligne
Rapport   Haut 

Re: gestion de l'insertion de lignes et de la saisie sur ces lignes
#2
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1539

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 18-10-2009 03h21
Bonsoir gmarin,

Selon mon expérience, la seule façon viable de contrôler une saisie utilisateur, c'est de passer par un Userform.
Ainsi, toute la saisie peut être contrôlée, vérifiée avant même que les données soient déposées sur la feuille.

Tu trouveras en pièce jointe ton classeur avec une façon de mettre en oeuvre ce point de vue.

Le module de code du Userform est le suivant :
Option Explicit
'--------------------------------------------------------------------------
' Auteur    : Didier FOURGEOT (myDearFriend!)  -  www.mdf-xlpages.com
' Date      : 18/10/2009
'--------------------------------------------------------------------------
Private Sub btnParcourir1_Click()
    Parcourir txtLien1
End Sub

Private Sub btnParcourir2_Click()
    Parcourir txtLien2
End Sub

Private Sub btnParcourir3_Click()
    Parcourir txtLien3
End Sub

Private Sub btnParcourir4_Click()
    Parcourir txtLien4
End Sub

Private Sub btnParcourir5_Click()
    Parcourir txtLien5
End Sub

Private Sub Parcourir(Ctrl As Control)
Dim Chemin As Variant
    Chemin = Application.GetOpenFilename("Fichier image (*.bmp; *.jpg; *.gif; *.png),*.bmp;*.jpg;*.gif;*.png", , "Choisir fichier image...")
    If Not Chemin = False Then
        Ctrl.Text = Chemin
    End If
End Sub

Private Sub btnInserer_Click()
Dim R As Range
Dim i As Byte
Dim Ok As Boolean
    'Contrôle la cohérence de la saisie
    If txtModele.Text = "" Then Exit Sub
    For i = 1 To 5
        If Controls("txtLieu" & i).Text <> "" And Controls("txtlien" & i).Text <> "" Then
            Ok = True
            Exit For
        End If
    Next i
    If Ok Then
        With Sheets("cars")
            'Créer nouvelle ligne
            .Rows("10").Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove
            'Recopier les formules en A et B
            .Range(.Cells(9, 1), .Cells(9, 2)).Copy
            .Range(.Cells(10, 1), .Cells(10, 2)).PasteSpecial Paste:=xlPasteFormulas
            Application.CutCopyMode = False
            'Insérer les données
            .Cells(10, 3).Value = txtModele
            InsereLien .Cells(10, 4), txtLien1, txtLieu1
            InsereLien .Cells(10, 5), txtLien2, txtLieu2
            InsereLien .Cells(10, 6), txtLien3, txtLieu3
            InsereLien .Cells(10, 7), txtLien4, txtLieu4
            InsereLien .Cells(10, 8), txtLien5, txtLieu5
        End With
    End If
End Sub

Private Sub InsereLien(R As Range, Lien As String, Titre As String)
'Insère le lien dans la feuille
    If Lien = "" Or Titre = "" Then Exit Sub
    With Sheets("cars")
        .Hyperlinks.Add Anchor:=R, Address:=Lien
        R.Hyperlinks(1).TextToDisplay = Titre
    End With
End Sub

Private Sub btnFin_Click()
Dim Plage As Range
Dim L As Long
    'Trier la base
    Application.ScreenUpdating = False
    With Sheets("cars")
        L = .Cells(.Rows.Count, 1).End(xlUp).Row
        Set Plage = .Range(.Cells(5, 1), .Cells(L, 8))
        Plage.Sort Key1:=.Range("C5"), Order1:=xlAscending, Header:=xlGuess, _
        OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom
    End With
    Application.ScreenUpdating = True
    'Fermer le formulaire
    Unload Me
    'Enregistrer sous...
    Application.Dialogs(xlDialogSaveAs).Show
End Sub
Par ailleurs, j'ai inclus dans le module de code de l'objet ThisWorkbook une façon de protéger ta feuille de façon un peu particulière : l'objectif et de protéger cette feuille (par mot de passe "cars") des actions utilisateur tout en permettant les traitements par macro sans avoir à enlever cette protection.

L'argument "UserInterfaceOnly" est l'élément qui permet ce type de verrouillage :

DANS LE MODULE DE CODE DE L'OBJET THISWORKBOOK :
Private Sub Workbook_Open()
    'Protéger la feuille tout en laissant les macros agir sur celle-ci
    Sheets("cars").Protect "cars", UserInterfaceOnly:=True
End Sub
En espérant que cette façon de faire te convienne...

Cordialement,

Nb:  pour permettre au plus grand nombre l'accès à ton fichier, je l'ai aussi converti pour être exploitable depuis les versions Excel antérieures à 2007.


Pièce jointe:
zip PourGmarin.zip   [ Taille: 31.30 Ko - Téléchargements: 586 ]

Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
Rapport   Haut 

Re: gestion de l'insertion de lignes et de la saisie sur ces lignes
#3
Régulier XLPages

Inscription: 05/10/2009
De 33210-Gironde

Messages: 49

Système d'exploitation:
PC
Version Excel utilisée:
2007
Posté le : 18-10-2009 08h28
Bonjour Didier,

Merci beaucoup pour cette solution à laquelle je n'aurais pas pensé.
Elle me convient à un poil près dans l'UserForm.
Les 5 lignes me permettent de saisir sur 1 ou les 5 lieux "actuels".
Le nombre de ces lieux va augmenter ultérieurement, ce n'est pas figé (ajout de colonnes issu d'une saisie sur autre feuille).
Est-ce que chaque chiffre de l'UserForm ne pourrait pas présenter une liste de choix scrutant la ligne 3, à partir de D3 ?

Autrechose, et je te présente mes excuses à l'avance pour ne pas y avoir pensé et l'avoir mentionné, dans les colonnes des "lieux", on ne peut cumuler plus de 8 modèles, au-delà, il y aura obligation de créer un autre lieu-annexe (ex: 1-1, 1-2, etc), donc affichage d'un message le rappelant et interdisant la saisie supplémentaire pour ce lieu.
Voilà, je n'ai pas tenu ma promesse précédente ..... mea culpa.


Gmarin.


Hors Ligne
Rapport   Haut 

Re: gestion de l'insertion de lignes et de la saisie sur ces lignes
#4
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1539

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 18-10-2009 11h35
Bonjour gmarin, le Forum,

Citation :
gmarin a écrit :
Merci beaucoup pour cette solution à laquelle je n'aurais pas pensé.
Elle me convient à un poil près dans l'UserForm.
Les 5 lignes me permettent de saisir sur 1 ou les 5 lieux "actuels".
Le nombre de ces lieux va augmenter ultérieurement, ce n'est pas figé (ajout de colonnes issu d'une saisie sur autre feuille).
Est-ce que chaque chiffre de l'UserForm ne pourrait pas présenter une liste de choix scrutant la ligne 3, à partir de D3 ?

Arf, j'étais sûr que tu allais m'annoncer encore un truc de ce genre... Tu dis que ça te convient "à un poil" près, mais je t'informe que le "poil" en question m'a pris environ 3 heures de travail cette nuit
Et pour la petite histoire : il était environ 2H00 du matin lorsque j'ai terminé une version intégrant une liste de choix des lieux, une zone de texte pour le Titre du lien, une zone de texte pour le lien en question et un bouton "Parcourir". Jusque là, j'étais satisfait et ça ressemblait beaucoup à ce que tu me proposes là. Cela dit, "j'étais" satisfait jusqu'à ce que je m'aperçoive que tu voulais visiblement pouvoir insérer plusieurs liens sur une même ligne... et là... et là je me suis rendu compte que cette solution n'étais donc pas adaptée et j'ai du recommencer le tout autrement pour te permettre l'insertion de plusieurs liens simultanément (5 au maximum d'après ton fichier). Et comme, une fois de plus, tu as oublié d'indiquer que 5 colonnes, donc 5 liens, ce n'est finalement pas figé... 

Alors je résume, tu as un Userform, avec :
- une zone de texte pour le modèle (colonne C)
- une liste déroulante pour choisir le lieu (1 à X pour le choix de la colonne D à ...)
- une zone de texte pour le Titre de lien (pour le libellé qui sera affiché dans la cellule contenant le lien)
- une zone de texte pour le chemin du lien en question.
- un bouton parcourir pour faciliter la saisie du dit chemin.

Comment fait-on pour saisir plusieurs liens simultanément pour une même ligne insérée ?

Citation :
gmarin a écrit :
...dans les colonnes des "lieux", on ne peut cumuler plus de 8 modèles, au-delà, il y aura obligation de créer un autre lieu-annexe (ex: 1-1, 1-2, etc), donc affichage d'un message le rappelant et interdisant la saisie supplémentaire pour ce lieu.

Là, je ne comprends pas. Que veux-tu dire et dans quelle situation exactement ?
Cela veut-il dire, par exemple, que si le compteur en D4 est égal à 8, on interdit la saisie d'un lien supplémentaire dans cette même colonne D ?

Cordialement,

Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
Rapport   Haut 

Re: gestion de l'insertion de lignes et de la saisie sur ces lignes
#5
Régulier XLPages

Inscription: 05/10/2009
De 33210-Gironde

Messages: 49

Système d'exploitation:
PC
Version Excel utilisée:
2007
Posté le : 18-10-2009 17h26
Bonjour Guy,

Je t'ai présenté mes excuses. Ta solution me convient parfaitement.
Je sais que ton travail n'a pas été une broutille de 5 minutes, je ne suis pas encore totalement "légume".
Mais ce n'est qu'à la suggestion de ta solution, que ma réflexion s'est portée sur le fait de l'évolution du nombre de lieux, donc de l'ajout de colonnes, que j'avais oublié de prendre en compte. Je ne suis pas un professionnel de l'utilisation des données et des tableurs, ni metteur au point et ma réflexion liée à mon âge ne me permettent pas d'apréhender nécessairement l'exacte portée du développement d'une action dans un contexte tel que celui où j'essaye de créer (grâce au Forum, et principalement ta personne) cette "chose" que je baptiserais "application", pour un Forum auquel j'adhère et qui ne dispose pas de personne compétente pour cette création, d'où mon bénévolat pour y parvenir.
C'est le "poil" qui fait qu'après réflexion sur cette solution, la convenance totale ne peut pas être de mise, et qu'il est bien logique que je t'en fasse part en y mettant les formes comme tu l'aura certainement observé.

Donc, en remontant de bas en haut :
Les compteurs de la ligne 2 indiquent qu'un modèle est présent dans un lieu.
Quand le compteur d'une ligne 2 (D2, E2 ...) est déjà à 8, on ne peut plus insérer dans la colonne correspondante.
Le tentative de saisie dans cette colonne doit se solder par le message "création lieu-annexe obligatoire" - validation : "annuler".
Cette insertion n'est pas effectuée depuis la feuille en cours.
Les compteurs de la ligne 4 indiquent le nombre de lieux comprenant un modèle disposant d'une photo documentaire.
Normalement, la saisie du lien hypertexte n'est pas obligatoirement simultanée à la saisie.
La photo documentaire peut être disponible ultérieurement.
Mais je peux très bien rentrer un lien bidon, et corriger après.

"Comment fait-on pour saisir plusieurs liens simultanément pour une même ligne insérée ?"

En supposant que j'arrive à un vingtaine de lieux, la ligne 3, à partir de la colonne D3 ira bien jusqu'à W3, les cellules étant libellées de 1 à 20. Et çà pourra continuer d'augmenter.
Les libellés dans la colonne C s'interprètent comme : "modèle type", ex: modèle type 106.
L'interprétation de "titre du lieu" ne correspond pas, ce devrait être : "modèle dans ce lieu" dont le nom peut différer d'un lieu à l'autre (ex : modèle 106 - lieu1, 106 XS - lieu2, 106 rallye ....)
Je pensais à une liste de choix là où il y a le numéro 1, avant "titre du lieu" scrutant "D3:?3" et me permettant un lieu de saisie.
Idem pour le chiffre 2, et ainsi de suite. Mais les 5 lignes de saisie ne sont pas une obligation, vu qu'une fois validé, on a accès aux cellules pour rajouter un modèle dans d'autres lieux.
L'essentiel ayant été atteint par le fait de l'insertion de ligne contrôlée, du report des formules, et de la saisie du nouveau répertoire de modèle avec au moins 1 modèle attribué à 1 lieu.
Donc, sur la ligne 1 de l'Userform, je pourrais par exemple choisir le lieu 4; sur la ligne 2, le lieu 8; sur la 3, le 10; sur la 4 le 15; sur la 5, le 20.


Encore une fois, Guy, il n'est pas facile pour une personne dont Excel et sa programmation et les tableurs en général ne sont pas l'occupation prédominante, de présenter un exemple de travail dans lequel tous les paramètres induits et actifs soient bien recensés et donc aucun d'oublié.
Puisses-tu m'en excuser.

Gmarin.




Hors Ligne
Rapport   Haut 

Re: gestion de l'insertion de lignes et de la saisie sur ces lignes
#6
Régulier XLPages

Inscription: 05/10/2009
De 33210-Gironde

Messages: 49

Système d'exploitation:
PC
Version Excel utilisée:
2007
Posté le : 18-10-2009 17h39
Re,

Pour information, le fichier sur lequel je travaille réellement, et à partir duquel je prépare les exemples pour les adapter une fois retoqués par les compétences du Forum, comprend 4 feuilles et fait 430k. Je ne peux donc pas le télécharger vers le Forum.
Je n'y tiens pas non plus, les données présentes dessus étant "confidentielles".
Ce qui fait que feuille par feuille, je prépare des exemples "similaires à" et ce n'est pas chose facile.
ce qui explique que je ne peux pas exposer une vue d'ensemble sans risquer de me tromper ici ou là, ou d'omettre involontairement des paramètres vitaux pour les personnes qui planchent sur ces exemples.

Si une solution peut se présenter pour contourner cet état de fait, tout en garantissant la confidentialité, je suis à l'écoute.

Gmarin.

Hors Ligne
Rapport   Haut 

Re: gestion de l'insertion de lignes et de la saisie sur ces lignes
#7
Accro XLPages

Inscription: 09/01/2008
De Montréal, Québec

Messages: 463

Système d'exploitation:
PC
Version Excel utilisée:
97 à 2016
Posté le : 18-10-2009 18h01
Bon, mise au point,

Je ne crois pas avoir été partie à cette discussion, lors je ne vois nullement la nécessité d'accepter ou de refuser des excuses.

C'est une méprise bien pardonnable.

Cordialement,

Guy

Hors Ligne
Rapport   Haut 

Re: gestion de l'insertion de lignes et de la saisie sur ces lignes
#8
Régulier XLPages

Inscription: 05/10/2009
De 33210-Gironde

Messages: 49

Système d'exploitation:
PC
Version Excel utilisée:
2007
Posté le : 18-10-2009 18h20
Bonjour Guy,

Méprise énorme, je te prie de m'en excuser.
C'était adressé à Didier, bien évidemment !

Mais je pense que Didier l'avait déjà soupçonné .

Gmarin.
Hors Ligne
Rapport   Haut 

Re: gestion de l'insertion de lignes et de la saisie sur ces lignes
#9
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1539

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 18-10-2009 18h57
Re gmarin, Guy,

Oui, j'avais un peu remarqué aussi pour la confusion des interlocuteurs...

En pièce jointe, ton fichier nouvelle version. Le module de code du Userform devient :
Option Explicit
'--------------------------------------------------------------------------
' Auteur    : Didier FOURGEOT (myDearFriend!)  -  www.mdf-xlpages.com
' Date      : 18/10/2009
'--------------------------------------------------------------------------
Private Sub UserForm_Initialize()
Dim maxCol As Integer
Dim C As Byte, i As Byte
    'Détermination du nombre de lieux maxi
    With Sheets("cars")
        maxCol = .Cells(3, .Columns.Count).End(xlToLeft).Column
    End With
    'Chargement des ComboBox correspondantes
    For C = 1 To 5
        For i = 1 To maxCol - 3
            Controls("cboLieu" & C).AddItem i
        Next i
    Next C
End Sub

Private Sub btnParcourir1_Click()
    Parcourir txtLien1
End Sub

Private Sub btnParcourir2_Click()
    Parcourir txtLien2
End Sub

Private Sub btnParcourir3_Click()
    Parcourir txtLien3
End Sub

Private Sub btnParcourir4_Click()
    Parcourir txtLien4
End Sub

Private Sub btnParcourir5_Click()
    Parcourir txtLien5
End Sub

Private Sub Parcourir(Ctrl As Control)
Dim Chemin As Variant
    Chemin = Application.GetOpenFilename("Fichier image (*.bmp; *.jpg; *.gif; *.png),*.bmp;*.jpg;*.gif;*.png", , "Choisir fichier image...")
    If Not Chemin = False Then
        Ctrl.Text = Chemin
    End If
End Sub

Private Sub btnInserer_Click()
Dim Ctrl As Control
Dim i As Byte, N As Byte
Dim Ok As Boolean
    'Contrôle la cohérence de la saisie
    If txtModele.Text = "" Then Exit Sub
    For i = 1 To 5
        If Controls("cboLieu" & i).ListIndex > -1 And Controls("txtLieu" & i).Text <> "" And Controls("txtlien" & i).Text <> "" Then
            N = Controls("cboLieu" & i).ListIndex
            '8 modèles maximum par lieu
            If Sheets("cars").Cells(2, 4 + N) > 7 Then
                MsgBox "Le lieu n°" & N + 1 & " contient déjà 8 modèles !"
                Ok = False
                Exit For
            Else
                Ok = True
            End If
        End If
    Next i
    If Ok Then
        With Sheets("cars")
            'Créer nouvelle ligne
            .Rows("10").Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove
            'Recopier les formules en A et B
            .Range(.Cells(9, 1), .Cells(9, 2)).Copy
            .Range(.Cells(10, 1), .Cells(10, 2)).PasteSpecial Paste:=xlPasteFormulas
            Application.CutCopyMode = False
            'Insérer les données
            .Cells(10, 3).Value = txtModele
            InsereLien cboLieu1.ListIndex, txtLien1, txtLieu1
            InsereLien cboLieu2.ListIndex, txtLien2, txtLieu2
            InsereLien cboLieu3.ListIndex, txtLien3, txtLieu3
            InsereLien cboLieu4.ListIndex, txtLien4, txtLieu4
            InsereLien cboLieu5.ListIndex, txtLien5, txtLieu5
        End With
        'RAZ formulaire (préparation pour saisie "de masse")
        For Each Ctrl In Me.Controls
            Select Case TypeName(Ctrl)
            Case "TextBox"
                Ctrl.Text = ""
            Case "ComboBox"
                Ctrl.ListIndex = -1
            End Select
        Next Ctrl
    End If
End Sub

Private Sub InsereLien(Id As Integer, Lien As String, Titre As String)
'Insère le lien dans la feuille
Dim R As Range
    If Id < 0 Or Lien = "" Or Titre = "" Then Exit Sub
    With Sheets("cars")
        Set R = .Cells(10, 4 + Id)
        .Hyperlinks.Add Anchor:=R, Address:=Lien
        R.Hyperlinks(1).TextToDisplay = Titre
    End With
End Sub

Private Sub btnFin_Click()
Dim Plage As Range
Dim L As Long
    'Trier la base
    Application.ScreenUpdating = False
    With Sheets("cars")
        L = .Cells(.Rows.Count, 1).End(xlUp).Row
        Set Plage = .Range(.Cells(5, 1), .Cells(L, 8))
        Plage.Sort Key1:=.Range("C5"), Order1:=xlAscending, Header:=xlGuess, _
        OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom
    End With
    Application.ScreenUpdating = True
    'Fermer le formulaire
    Unload Me
    'Enregistrer sous...
    Application.Dialogs(xlDialogSaveAs).Show
End Sub

Private Sub btnAnnuler_Click()
    Unload Me
End Sub

De plus, en réponse à :
Citation :
gmarin a écrit : Re,

Pour information, le fichier sur lequel je travaille réellement, et à partir duquel je prépare les exemples pour les adapter une fois retoqués par les compétences du Forum, comprend 4 feuilles et fait 430k. Je ne peux donc pas le télécharger vers le Forum.
Je n'y tiens pas non plus, les données présentes dessus étant "confidentielles".
Ce qui fait que feuille par feuille, je prépare des exemples "similaires à" et ce n'est pas chose facile.
ce qui explique que je ne peux pas exposer une vue d'ensemble sans risquer de me tromper ici ou là, ou d'omettre involontairement des paramètres vitaux pour les personnes qui planchent sur ces exemples.

Si une solution peut se présenter pour contourner cet état de fait, tout en garantissant la confidentialité, je suis à l'écoute.

Gmarin.

Pour moi, l'analyse d'un tel fichier, dans sa globalité, ne rentre plus dans le cadre des objectifs d'un forum de discussions. En tout cas, ce n'est pas dans cette optique que j'ai créé celui d'XLpages.
Par ailleurs, j'ai dans l'idée que ce n'est pas forcément la vue d'un projet entier qui évitera les incompréhensions de celui qui apporte son aide. L'intervenant restera toujours avec un regard "extérieur" et souvent, seul le créateur du dit projet reste à même d'expliquer ses choix de développements.

Cordialement,

Pièce jointe:
zip PourGmarin2.zip   [ Taille: 33.21 Ko - Téléchargements: 550 ]
Edité par myDearFriend! le 18/10/2009 19:27:43

Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
Rapport   Haut 

Re: gestion de l'insertion de lignes et de la saisie sur ces lignes
#10
Régulier XLPages

Inscription: 05/10/2009
De 33210-Gironde

Messages: 49

Système d'exploitation:
PC
Version Excel utilisée:
2007
Posté le : 18-10-2009 19h15
Merci Didier.

C'est exactement ce qu'il fallait.
Avec mes remerciements,

GMarin.
Hors Ligne
Rapport   Haut 


Vous pouvez voir les sujets.
Vous ne pouvez pas débuter de nouveaux sujets.
Vous ne pouvez pas répondre aux contributions.
Vous ne pouvez pas éditer vos contributions.
Vous ne pouvez pas effacez vos contributions.
Vous ne pouvez pas ajouter de nouveaux sondages.
Vous ne pouvez pas voter en sondage.
Vous ne pouvez pas attacher des fichiers à vos contributions.
Vous ne pouvez pas poster sans approbation.

[Recherche avancée]


Qui consulte actuellement ce sujet ?   1 Utilisateur(s) anonymes