Rapport de message :*
 

Re: sous menu contextuel

Titre du sujet : Re: sous menu contextuel
par myDearFriend! le 13/01/2008 01:08:23

Bonsoir,

Je l'ai dit, je ne suis pas convaincu qu'une demande relative aux CommandBars soit vraiment bienvenue ici pour l'instant... Mais bon, juste histoire d'apporter une réponse au sujet, tu peux peut-être jeter un oeil au fichier en pièce jointe PowerPlus.

J'ai utilisé le code ci-dessous pour constituer le sous-menu contextuel de cellule :
Option Explicit
' myDearFriend!  -  www.mdf-xlpages.com

Sub CreerSousMenu()
Dim cmdBarPp As CommandBarPopup
Dim NomMenu As String

    NomMenu = "Note"    'Menu principal conteneur
    
    With Application.CommandBars("Cell")
        On Error Resume Next
        Set cmdBarPp = .Controls(NomMenu)
        On Error GoTo 0
        If Not cmdBarPp Is Nothing Then Exit Sub
        Set cmdBarPp = .Controls.Add(Type:=msoControlPopup, Temporary:=True)
    End With
    
    With cmdBarPp
       .Caption = NomMenu
       .BeginGroup = True
       
        With .Controls.Add(Type:=msoControlButton)  'Elément 1
            .Caption = "Ajouter"
            .OnAction = "MacroAjout"
        End With
        With .Controls.Add(Type:=msoControlButton)  'Elément 2
            .Caption = "Supprimer"
            .OnAction = "MacroSuppr"
        End With
        With .Controls.Add(Type:=msoControlButton)  'Elément 3
            .Caption = "Editer"
            .OnAction = "MacroEdit"
        End With
    End With
End Sub

Sub SupprSousMenu()
    On Error Resume Next
    Application.CommandBars("Cell").Controls("Note").Delete
End Sub


J'espère que cet exemple pourra répondre à ta curiosité PowerPlus.
Pour ma part, et compte tenu de mon avis déjà exprimé par ailleurs, je ne m'attarderai pas d'avantage sur ce sujet ici.

Cordialement,